VB.NET-TIPS などプログラミングについて

2018/03/22

追記元のテキストファイルを最初に全て読み込み、追記先のテキストファイルに追加書込みを行います。テキストファイルのコードは Shift-JIS を想定していますので、エンコーディングは Shift-JIS に設定しています。テキストファイルの読み込みには System.IO.File.ReadAllText を用います。テキストファイルの追加書込みには System.IO.File.AppendAllText を用います。

System.IO.File.ReadAllText 関数について

Public Shared Function ReadAllText(path As String, encoding As Encoding) As String
path:
    読み取り用に開かれるファイルパス。
encoding
    ファイルの内容に適用されるエンコーディング。
戻り値:
    ファイルのすべての行を格納している文字列。

System.IO.File.AppendAllText 関数について

Public Shared Sub AppendAllText(path As String, contents As String, encoding As Encoding)
path:
    指定した文字列の追加先となるファイル。
contents
    ファイルに追加する文字列。
encoding
    使用する文字エンコーディング。

テキストファイル追記処理

    ''' -----------------------------------------------------------------------
    ''' 
    ''' テキストファイル追記処理
    ''' 
    ''' <param name="astrSrcFileName">追記元データファイル名</param>
    ''' <param name="astrDesFileName">追記先データファイル名</param>
    ''' 正常終了:true エラー発生:false
    ''' 作成したファイルを送信ファイルに追記する
    ''' -----------------------------------------------------------------------
    Function AppendTextFile(ByVal astrSrcFileName As String,
                              ByVal astrDesFileName As String) As Boolean
        '戻り値初期化
        AppendTextFile = False

        Try
            Dim strFileText As String = ""
            Dim decFileSize As Decimal = 0        'データファイルサイズ

            '追記先データファイル存在確認
            If System.IO.File.Exists(astrDesFileName) Then
                'ファイルサイズ取得
                decFileSize = FileLen(astrDesFileName)
            End If

            If decFileSize = 0 Or decFileSize = 1 Then
                'ファイルサイズが0または1バイトの場合、送信ファイル置き換え（上書き）
                My.Computer.FileSystem.CopyFile(astrSrcFileName, astrDesFileName, True)
            Else
                'それ以外の場合、送信ファイルに追記
                Dim enc As System.Text.Encoding = System.Text.Encoding.GetEncoding("Shift_JIS")
                '作成したファイルのテキストを取得
                strFileText = System.IO.File.ReadAllText(astrSrcFileName, enc)
                '送信ファイルの末尾に追記
                System.IO.File.AppendAllText(astrDesFileName, strFileText, enc)
            End If

            '正常終了
            AppendTextFile = True

        Catch ex As Exception
            'エラー処理が必要な場合は、ここに記述する
        End Try
    End Function

System.IO.Directory.GetFiles 関数について

Public Shared Function GetFiles (path As String) As String()
path:
    検索するディレクトリの相対パスまたは絶対パス。 この文字列の大文字と小文字は区別されません。
戻り値:
    指定したディレクトリ内のファイルの完全名 (パスを含む) の配列。
    ファイルが見つからない場合は空の配列。(空と言うことはLengthが 0 のString配列)

System.IO.File.Create 関数について

Public Shared Function Create (path As String) As FileStream
path:
    作成するファイルのパスと名前。
戻り値:
    FileStream で指定したファイルへの読み取り/書き込みアクセスを提供する path

指定フォルダ内の全ファイルをクリア

    ''' -----------------------------------------------------------------------
    ''' 
    ''' 指定フォルダ内の全ファイルをクリア
    ''' 
    ''' <param name="astrDesFolderName">指定フォルダ</param>
    ''' True:正常, False:エラー
    ''' -----------------------------------------------------------------------
    Function ClearFolderFile(ByVal astrDesFolderName As String) As Boolean
        '戻り値初期化
        ClearFolderFile = False
        Try
            '指定フォルダ内の全ファイルを取得
            Dim arrFiles() As String = System.IO.Directory.GetFiles(astrDesFolderName)

            '全ファイルクリア
            For Each strFile As String In arrFiles
                'File.Create メソッドを使用してファイルを作成する
                Using fs As System.IO.FileStream = System.IO.File.Create(strFile)
                    'ファイルクローズ
                    fs.Close()
                End Using
            Next

            '正常終了
            Return True

        Catch ex As Exception
            'エラー処理が必要な場合は、ここに記述する
        End Try
    End Function

System.IO.Directory.GetFiles 関数について

Public Shared Function GetFiles (path As String) As String()
path:
    検索するディレクトリの相対パスまたは絶対パス。 この文字列の大文字と小文字は区別されません。
戻り値:
    指定したディレクトリ内のファイルの完全名 (パスを含む) の配列。
    ファイルが見つからない場合は空の配列。(空と言うことはLengthが 0 のString配列)

System.IO.File.Delete 関数について

Public Shared Sub Delete (path As String)
path:
    検索するディレクトリの相対パスまたは絶対パス。 この文字列の大文字と小文字は区別されません。

指定フォルダ内の全ファイル削除関数

    ''' -----------------------------------------------------------------------
    ''' 
    ''' 指定フォルダ内の全ファイルを削除
    ''' 
    ''' <param name="astrDesFolderName">指定フォルダ</param>
    ''' True:正常, False:エラー
    ''' -----------------------------------------------------------------------
    Function DeleteFolder(ByVal astrDesFolderName As String) As Boolean
        '戻り値初期化
        DeleteFolder = False
        Try
            '指定フォルダ内の全ファイルを取得
            Dim arrFiles() As String = System.IO.Directory.GetFiles(astrDesFolderName)

            '全ファイル削除
            For Each strFile As String In arrFiles
                System.IO.File.Delete(strFile)
            Next

            '正常終了
            Return True

        Catch ex As Exception
            'エラー処理が必要な場合は、ここに記述する
        End Try
    End Function

System.IO.Directory.GetFiles 関数について

Public Shared Function GetFiles (path As String) As String()
path:
    検索するディレクトリの相対パスまたは絶対パス。 この文字列の大文字と小文字は区別されません。
戻り値:
    指定したディレクトリ内のファイルの完全名 (パスを含む) の配列。
    ファイルが見つからない場合は空の配列。(空と言うことはLengthが 0 のString配列)

System.IO.Directory.GetDirectories 関数について

Public Shared Function GetDirectories (path As String) As String()
path:
    検索するディレクトリの相対パスまたは絶対パス。 この文字列の大文字と小文字は区別されません。
戻り値:
    指定したパス内のサブディレクトリのフルネーム (パスを含む) の配列。
    ディレクトリが見つからない場合は空の配列。(空と言うことはLengthが 0 のString配列)

フォルダコピー関数

    ''' -----------------------------------------------------------------------
    ''' 
    ''' フォルダコピー(サブフォルダ以下も含む)
    ''' 
    ''' <param name="astrSrcFolderName">コピー元フォルダ</param>
    ''' <param name="astrDesFolderName">コピー先フォルダ</param>
    ''' True:正常, False:エラー
    ''' -----------------------------------------------------------------------
    Function CopyFolder(ByVal astrSrcFolderName As String, ByVal astrDesFolderName As String) As Boolean
        '戻り値初期化
        CopyFolder = False
        Try
            'コピー先のフォルダがないときは作る
            If Not System.IO.Directory.Exists(astrDesFolderName) Then
                System.IO.Directory.CreateDirectory(astrDesFolderName)
                '属性もコピー
                System.IO.File.SetAttributes(astrDesFolderName, System.IO.File.GetAttributes(astrSrcFolderName))
            End If

            'コピー先のフォルダ名の末尾に"\"をつける
            If astrDesFolderName.Chars((astrDesFolderName.Length - 1)) <> System.IO.Path.DirectorySeparatorChar Then
                astrDesFolderName &= System.IO.Path.DirectorySeparatorChar
            End If

            'コピー元のフォルダにあるファイルをコピー
            Dim ArrFiles As String() = System.IO.Directory.GetFiles(astrSrcFolderName)
            Dim strFile As String
            For Each strFile In ArrFiles
                System.IO.File.Copy(strFile, astrDesFolderName + System.IO.Path.GetFileName(strFile), True)
            Next

            'コピー元のフォルダにあるフォルダをコピー(再帰呼出)
            Dim ArrDirs As String() = System.IO.Directory.GetDirectories(astrSrcFolderName)
            Dim strDir As String
            For Each strDir In ArrDirs
                If CopyFolder(strDir, astrDesFolderName + System.IO.Path.GetFileName(strDir)) = False Then
                    '再帰呼出での内部のフォルダのコピーがエラーの場合
                    Return False
                End If
            Next

            '正常終了
            Return True

        Catch ex As Exception
            'エラー処理が必要な場合は、ここに記述する
        End Try
    End Function