VB.NET-TIPS などプログラミングについて

今回はBHT-BASICの画面への表示について説明したいと思います。
私が使った BHT-1306B ですが、液晶画面の仕様は以下の様になっています。

・ドット数：240(横)×320(縦)ドット

・表示文字数：（文字フォントサイズと画面モードで変わります）

フォントサイズ	画面モード	表示文字数(桁×行)	文字ﾄﾞｯﾄ数(横×縦)
標準	ANKモード	20桁×20行	12×16
標準	漢字モード	8桁×10行(16桁×10行)	30×30(15×30)
小	ANKモード	20桁×20行	12×16
小	漢字モード	10桁×13行(20桁×13行)	24×24(12×24)
40	ANK・漢字	6桁×8行(12桁×8行)	40×40(20×40)
30	ANK・漢字	8桁×10行(16桁×10行)	30×30(15×30)
24	ANK・漢字	10桁×13行(20桁×13行)	24×24(12×24)
16	ANK・漢字	15桁×20行(30桁×20行)	16×16(8×16)

画面モードの切り替えはSCREENステートメント（命令）で行います。
また、フォントサイズの指定は、 OUT命令により&H6080のアドレスに値を出力することで行います。
ソース的には以下の様な感じです。

	SCREEN 0		'ANKモード
	SCREEN 1		'漢字モード
	OUT & H6080, 0 	'標準フォント
	OUT &H6080, 1 	'小フォント
	OUT &H6080, 40 	'縦横40ドット
	OUT &H6080, 30 	'縦横30ドット
	OUT &H6080, 24 	'縦横24ドット

そこで各モードとフォント設定でどの様な表示なるのかを試してみました。

■標準フォント・ANKモード

	OUT &H6080, 0 	'標準フォント
	SCREEN 0		'ANKモード
	DIM I%
	FOR I% = 1 TO 20 '20×20
		PRINT "01234567890123456789";
	NEXT I%
	WAIT 0, &h01	'キー入力待ち
	END

ここで、FOR文が出てきましたが、 このステートメントはいろんな言語で既によく使われていますのでFOR文自体の 説明はしませんが、20文字の文字列を20回画面に表示を行います。 実行結果は以下の様になります。



■標準フォント・漢字モード

	OUT &H6080, 0 	'標準フォント
	SCREEN 1		'漢字モード
	DIM I%
	FOR I% = 1 TO 10 '8×10
		PRINT "０１２３４５６７";
	NEXT i%
	WAIT 0, &h01	'キー入力待ち
	END

■小フォント・ANKモード

	SCREEN 0		'ANKモード
	OUT &H6080, 1 	'小フォント
	DIM I%
	FOR I% = 1 TO 20 '20×20
		PRINT "01234567890123456789";
	NEXT i%
	WAIT 0, &h01	'キー入力待ち
	END

シミュレーションでの表示ですが、「標準フォント・ANKモード」と同じになりました。

■小フォント・漢字モード

	SCREEN 1		'漢字モード
	OUT &H6080, 1 	'小フォント
	DIM I%
	FOR I% = 1 TO 13 '10×13
		PRINT "０１２３４５６７８９";
	NEXT i%
	WAIT 0, &h01	'キー入力待ち
	END

■40ドットフォント

	OUT &H6080, 40 	'縦横40ドット
	DIM I%
	FOR I% = 1 TO 8 '6×8
		PRINT "０１２３４５";
	NEXT i%
	WAIT 0, &h01	'キー入力待ち
	END

■30ドットフォント

	OUT &H6080, 30 	'縦横30ドット
	DIM I%
	FOR I% = 1 TO 10 '8×10
		PRINT "０１２３４５６７";
	NEXT i%
	WAIT 0, &h01	'キー入力待ち
	END

■24ドットフォント

	OUT &H6080, 24 	'縦横24ドット
	DIM I%
	FOR I% = 1 TO 13 '10×13
		PRINT "０１２３４５６７８９";
	NEXT i%
	WAIT 0, &h01	'キー入力待ち
	END

この最後の表示は、「小フォント・漢字モード」と同じ結果になります。

私がBHT-1306Bを使ったシステムを作成した時には、 漢字の文字数などから判断して「小フォント・漢字モード」の表示を採用しました。

=====
2016/04/02：の時の情報

今回はBHT-BASICの演算子について説明したいと思います。
BHT-BASICには、算術演算子、関係演算子、論理演算子、関数演算子、文字列演算子と 普通の言語にはだいたいそろっている演算子があります。

■演算子の優先順位

優先順位	演算子名称	演算子
1	括弧	( ) 括弧の中が優先して演算
2	関数演算子	組込み関数,ユーザ関数の実行
3	算術演算子	※演算子の中で更に優先度がある 優先順位 演算 演算子 1 負号 - 2 乗算、除算 * , / 3 剰余演算 MOD 4 加算、減算 + , -
4	関係演算子	= , <> , >< , < , > , <= , >= , =< , =>
5	論理演算子	※演算子の中で更に優先度がある 優先順位 演算 演算子 1 否定 NOT 2 論理積 AND 3 論理和 OR 4 排他的論理和 XOR
6	文字列演算子

演算子は特に目新しいものは無く、よくあるものばかりですので、 各演算子毎に細かくは記しませんが、少し注意するものをピックアップします。

■算術演算子・剰余演算（MOD）

MODは割り算の余りを返すものです。 以下の例の様に数値は四捨五入し整数にしてからMOD演算が行われます。

	PRIVATE X%, Y%, R%
	X% = 10
	Y% = 3
	R% = X% MOD Y%	'X%をY%で割った余り
	PRINT "R%=" ; R%
	R% = 10 MOD 4.1	'4.1を四捨五入し結果 10 MOD 4
	PRINT "R%=" ; R%
	R% = -10 MOD -4.5 '-4.5を四捨五入し結果 -10 MOD -5
	PRINT "R%=" ; R%
	
	Wait 0, &h01	'キー入力待ち
	END

■オーバーフローとゼロによる除算

演算結果がオーバーフローしたり、ゼロで割った場合には実行時エラーが発生します。 以下のソースはその例を示します。

	ON ERROR GOTO MAIN.ERR	'エラー宣言
	PRIVATE X%, Y%
	X% = 32767		'整数型のMAX値
	PRINT "TEST-1"
	Y% = X% / 0		'ゼロで割る
	PRINT "TEST-2"
	Y% = X% + 1		'整数型のオーバーフロー
	
	Wait 0, &h01	'キー入力待ち
	END

MAIN.ERR:
	'エラーコードと発生アドレス表示
	PRINT "ERR=" + HEX$(ERR) + " : ERL=" + HEX$(ERL)
	RESUME NEXT		'エラー発生の次の行に戻る

■関係演算子について

関係演算子は2個の式を比較して、真「－1」または偽「0」を返します。 この値を使って、プログラムの流れを制御できます。 以下のソースは、IF文を使った各関係演算子の例を示します。

また、関係演算子の計算結果を変数に入れて使うこともできます。

	SCREEN 1 '標準漢字モードを指定
	PRIVATE X%
	'各関係演算子の例	
	IF 1 = 1  THEN PRINT "[=] :等しい"     ENDIF
	IF 0 <> 1 THEN PRINT "[<>]:等しくない" ENDIF
	IF 0 < 1  THEN PRINT "[<] :小さい" ENDIF
	IF 1 > 0  THEN PRINT "[>] :大きい" ENDIF
	IF 0 <= 1 THEN PRINT "[<=]:以下" ENDIF
	IF 1 => 0 THEN PRINT "[=>]:以上" ENDIF
	PRINT "-----"
	'比較を式に代入
	X% = (1 = 1): PRINT "等しい="; X%
	X% = (0 = 1): PRINT "等しくない="; X%
	Wait 0, &h01	'キー入力待ち
	END

■論理演算子を式で使う

論理演算子は、複数の関係演算子での判定結果を関連付ける演算子です。

	OUT &H6080, 1 '小フォントを指定
	PRIVATE X%, Y%, Z%
	'NOT
	Z% = NOT(0): PRINT "NOT (0)=" ;Z%
	Z% = NOT(NOT(0)): PRINT "NOT(NOT((0))=" ;Z%
	Z% = NOT(1): PRINT "NOT (1)=" ;Z%
	'AND
	Z% = 0 AND 0: PRINT "(0) AND (0)=" ;Z%
	Z% = 0 AND 1: PRINT "(0) AND (1)=" ;Z%
	Z% = 1 AND 0: PRINT "(1) AND (0)=" ;Z%
	Z% = 1 AND 1: PRINT "(1) AND (1)=" ;Z%
	'OR
	Z% = 0 OR 0: PRINT "(0) OR (0)=" ;Z%
	Z% = 0 OR 1: PRINT "(0) OR (1)=" ;Z%
	Z% = 1 OR 0: PRINT "(1) OR (0)=" ;Z%
	Z% = 1 OR 1: PRINT "(1) OR (1)=" ;Z%
	'XOR
	Z% = 0 XOR 0: PRINT "(0) XOR (0)=" ;Z%
	Z% = 0 XOR 1: PRINT "(0) XOR (1)=" ;Z%
	Z% = 1 XOR 0: PRINT "(1) XOR (0)=" ;Z%
	Z% = 1 XOR 1: PRINT "(1) XOR (1)=" ;Z%
	
	Wait 0, &h01	'キー入力待ち
	END

■文字列演算子について

文字列の演算では結合しかなく、+マークで行います。 また、数値の様に文字列の比較ができます。

	SCREEN 1 '標準漢字モードを指定
	'文字列連結
	PRIVATE X$, Y$, Z$
	X$ = "123": Y$ = "ABC"
	Z$ = "連結=" + X$ + ":" + Y$
	PRINT Z$
	PRINT "-----"
	'各関係演算子の例	
	IF "123" =  "123" THEN PRINT "[=] :等しい"     ENDIF
	IF "012" <> "123" THEN PRINT "[<>]:等しくない" ENDIF
	IF "001" <  "002" THEN PRINT "[<] :小さい" ENDIF
	IF "003" >  "002" THEN PRINT "[>] :大きい" ENDIF
	PRINT "-----"
	'文字列の長さが異なる
	IF "123" <> "12"  THEN PRINT "[<>]:等しくない" ENDIF
	IF "12"  <  "123" THEN PRINT "[<] :小さい" ENDIF
	IF "123" >  "12"  THEN PRINT "[>] :大きい" ENDIF

	Wait 0, &h01	'キー入力待ち
	END

=====
2016/04/02：の時の情報

ハンディターミナルの開発言語であるBHT-BASIC4.0についての4回目になります。 今回はユーザ定義関数について説明したいと思います。

■ユーザ定義関数

ユーザ定義関数とは、BHT-BASICが既に備わっている関数ではなく、 ユーザが任意で作成する関数のことです。 ユーザが定義できる関数には大きく分けて2種類のものがあり、 DEF FN及びFUNCTIONで定義される値を返す関数と、 SUBで定義される値を返さない関数があります。
このうちFUNCTION関数、SUB関数はDECLAREステートメントで宣言することで 別モジュールで使用することができます。

DEF FN関数及びFUNCTION関数には返す値により 関数の最後にデータ型を示す記号を付加します。

ユーザ定義関数のデータ型	DEF FN関数の書式	FUNCTION関数の書式
整数型	FN関数名%	関数名%
長整数型	FN関数名&	関数名&
実数型	FN関数名	関数名
文字型	FN関数名$	関数名$
文字型 (文字列長指定)	FN関数名$(・・・)[NNN] （NNN：に文字列長指定）	関数名$(・・・)[NNN] （NNN：に文字列長指定）

値を返す関数は、私は専らFUNCTION関数を使い、DEF FN関数は殆んど使っていません。 なぜならば、DEF FN関数ではSTATIC変数が使えませんし、 他のモジュールから参照することができないからです。

尚、値を返さない関数は当然のことSUB関数で宣言します。

関数には値を渡さない場合は引数の宣言をしませんが、 値が必要な場合には関数の宣言のところで引数の宣言を行います。 この引数の渡し方には、値渡し（call by value）と、 参照渡し（call by reference）の2種類があります。

■値渡し・参照渡し

以下のソース「MODULE1.SRC」を見てください。

'File	[MODULE1.SRC]
	FUNCTION Func1%(BYVAL P%)
		Func1% = P% * 2	'引数を2倍して戻す
	END FUNCTION

	FUNCTION Func2%(BYREF P%)
		Func2% = P% * 2	'引数を2倍して戻す
		P% = P% + 1		'引数に+1する
	END FUNCTION
	
	DIM	I%
	I% = 10
	PRINT "Func1%=" ; Func1%(I%)
	PRINT "I%=" ; I%	'I%は変わらない
	PRINT "Func2%=" ; Func2%(I%)
	PRINT "I%=" ; I%	'I%は変化した!!
	
	Wait 0, &h01	'キー入力待ち
	END

これを実行すると以下の表示の様になります。

FUNCTION関数の宣言はFUNCTIONで始まり、END FUNCTIONで終わります。 関数の引数は仮引数名で宣言し、値渡しはBYVALキーワードで宣言し、 参照渡しはBYREFキーワードで宣言します。 BYVAL、BYREFが無い場合はデフォルトで値渡しになりますが、 引数の意味合いをはっきりさせるため、必ずこのキーワードを付加すべきだと思います。

関数の戻り値は関数名に値を代入することで戻します。
このソースでは、Func1%は値渡し、Func2%は参照渡しの例です。

=====
2016/04/02：の時の情報

ハンディターミナルの開発言語であるBHT-BASIC4.0についての3回目になります。 前回は変数宣言について説明しましたが、追加でいくつかの内容を記します。

■変数宣言されない変数

コンパイラの指定で「オプション」の「宣言されていない変数をエラーにする」チェックをOFFすると 変数の宣言が無くても、変数を初めて使用した時点で変数が宣言されたことになります。
以下のソース「MODULE1.SRC」を見てください。

'File	[MODULE1.SRC]

	Sub Test1
		WK$ = "ABC"			'自動変数[WK$]宣言
		Print "WK$=" + WK$	'Test1内変数[WK$]を参照
	End Sub

	WK$ = "123"				'モジュール変数[WK$]宣言
	
	Sub Test2
		Print "WK$=" + WK$	'モジュール変数[WK$]を参照
		WK$ = "***"			'モジュール変数[WK$]を参照・変更
		Print "WK$=" + WK$	'モジュール変数[WK$]を参照
	End Sub

	Call Test1		'MODULE2.SRCのTest1関数をコール
	Call Test2		'MODULE2.SRCのTest1関数をコール
	Print "WK$=" + WK$	'モジュール変数[WK$]を参照
	WK$ = "@@@"			'上のモジュール変数[WK$]と同じ
	Print "WK$=" + WK$	'モジュール変数[WK$]を参照
	Wait 0, &h01	'キー入力待ち
	END

これを実行すると以下の表示の様になります。

コンパイラはソースの先頭からスキャンするため、 最初に関数Test1の中のWK$が出てきた時に、自動変数として宣言します。 この変数はTest1の中でのみ有効です。

Test1のすぐ下でWK$への値に代入が出てきた時点で、 このモジュール内の変数として、WK$が有効となります。

関数Test2の中でWK$を使用していますが、 これは直前のモジュール変数を参照することになります。

上記のソースを実行すると、考え方としてはCall Test1から走るような感覚です。
この例でも分かるように、自動変数を許可するとどこで変数の値が変化してしまうのかが デバッグ時に混乱してしまいます。 それで通常は、コンパイラオプションの「宣言されていない変数をエラーにする」チェックを ONにして、変数は必ず宣言する様にします。

■文字列変数について

今まで気にせずに文字列変数を宣言してきましたが、 実は文字列の格納できる長さについての制限があります。 以下のソースを見てください。

モジュール変数を例にしていますが、最初はWK1$として変数名そのままで宣言しています。 この場合、文字列として格納できる最大の文字数は 40 までです。 暗黙の了解として文字数のMAXを宣言しなければ、40なのです。これは忘れがちなので注意して下さい。
（配列変数の場合は20文字がデフォルトです）
また、この文字数の最大を超えて値を設定すると実行時エラーとして「0Fh：文字列長が範囲外です。」が発生します。 以下のソースでも7行目でエラーが発生します。

さて、2番目の宣言WK2$[10]ですが、これはWK2$の文字数が最大10であることを宣言しています。 そこで以下のソースの中で7行目をコメント行にして実行すると、当然13行目でエラーが発生します。

'File	[MODULE1.SRC]
	PRIVATE WK1$
	WK1$ = "123"
	Print "WK1$=" + WK1$	'モジュール変数[WK$]を参照
	WK1$ = "0123456789012345678901234567890123456789"
	Print "WK1$=" + WK1$	'モジュール変数[WK$]を参照
	WK1$ = "0123456789012345678901234567890123456789@"
	Print "WK1$=" + WK1$	'モジュール変数[WK$]を参照

	PRIVATE WK2$[10]
	WK2$ = "123"
	Print "WK2$=" + WK2$	'モジュール変数[WK$]を参照
	WK1$ = "0123456789@"
	Print "WK1$=" + WK1$	'モジュール変数[WK$]を参照
	
	Wait 0, &h01	'キー入力待ち
	END

ちなみに、文字列の文字数宣言で最大は8192文字までです。

文字列処理はエラーが発生しない様に、文字数宣言を超えない様に文字数を大きくとるか、 または、最大文字数を超えない様な文字列連結の関数を作るかするしかないと思います。

=====
2016/04/02：の時の情報

ハンディターミナルの開発言語であるBHT-BASIC4.0についての2回目ですが、 今回はデータ型に続いて変数宣言や、式、演算子などについて説明します。

一般的にプログラム言語で存在する、グローバル変数、モジュール変数、ローカル変数がBHT-BASICにもあります。 グローバル変数、モジュール変数とはユーザが宣言する関数の外で静的に存在する変数です。 ローカル変数とはユーザ関数の中で一時的に存在する変数のことです。

それでは各変数それぞれについて詳しくみていきます。

■グローバル変数

ユーザが宣言する関数の外で、PUBLIC または GLOBALの命令語（ステートメント） で変数を宣言すると、グローバル変数として宣言できます。
PUBLIC と GLOBALですがどちらで宣言してもいい様ですが、 それぞれ違いがあります。 まずはPUBLIC宣言のソースの例です。 この例では「MODULE1.SRC」と「MODULE2.SRC」の２つのソースがあります。 尚、プロジェクトのプロパティでメインモジュールとして「MODULE1.SRC」を指定してあります。

'File	[MODULE1.SRC]
	PUBLIC PDT1%		'グローバル変数宣言・整数型
	PUBLIC PDT2$[256]	'グローバル変数宣言・文字列型
	Declare Sub Test1	'別ソースの関数を使用する為に型宣言

Main
	PDT1% = 100		'グローバル変数に値代入
	PDT2$ = "1234567890"
	Call Test1		'MODULE2.SRCのTest1関数をコール
	Wait 0, &h01	'キー入力待ち
	END

'File	[MODULE2.SRC]

'テスト関数の宣言
	Sub Test1
		Print "PDT1%=" ; PDT1%	'グローバル変数[PDT1%]を参照
		Print "PDT2$=" + PDT2$	'グローバル変数[PDT2$]を参照
	End Sub

これを実行すると以下の表示の様になります。

PUBLIC宣言はソースファイルのどこか一カ所で行えば、 別のソースでそれを参照する場合は、宣言なしでその変数名を使えば 参照できます。

同じ変数名で別のソースでPUBLIC宣言すると二重定義エラーがリンク時に発生します。 但し、同じ変数名でもモジュール変数として宣言すれば別の変数として扱われますので、 注意が必要です。

上記のソースで宣言した、「PDT1%」「PDT2$」を今度はGLOBALで宣言します。 今回の場合は「MODULE2.SRC」の方にも同じ宣言をしないと、 リンク時に変数宣言エラーが発生します。

'File	[MODULE1.SRC]
	GLOBAL PDT1%		'グローバル変数宣言・整数型
	GLOBAL PDT2$[256]	'グローバル変数宣言・文字列型
	Declare Sub Test1	'別ソースの関数を使用する為に型宣言

Main
	PDT1% = 100		'グローバル変数に値代入
	PDT2$ = "1234567890"
	Call Test1		'MODULE2.SRCのTest1関数をコール
	Wait 0, &h01	'キー入力待ち
	END

'File	[MODULE2.SRC]
	GLOBAL PDT1%		'グローバル変数宣言・整数型
	GLOBAL PDT2$[256]	'グローバル変数宣言・文字列型

'テスト関数の宣言
	Sub Test1
		Print "PDT1%=" ; PDT1%	'グローバル変数[PDT1%]を参照
		Print "PDT2$=" + PDT2$	'グローバル変数[PDT2$]を参照
	End Sub

どちらの方法でも同じ結果になるのですが、 PUBLIC または GLOBALのどちらがいいとも言えません。
PUBLICの場合は、他のソースで宣言しなくても使えるので楽と言えば楽かもしれませんが、 変数が多くなりソースファイルの数が増えると管理が厄介です。
但し、PUBLICを宣言するところを一カ所に限定し、 変数の命名規則でPUBLICだとわかるプリフィックスを先頭に付けるのも方法かもしれません。

GLOBALはその変数を参照しているソースファイルで同じ宣言を行う必要が在ります。 この宣言を別ファイルにし、変数の宣言のみのソースとして、各ソースファイルで インクルードすることで煩雑ではなくなると思います。以下のソースがその例です。

'File	[TESTINC.INC]
	GLOBAL PDT1%		'グローバル変数宣言・整数型
	GLOBAL PDT2$[256]	'グローバル変数宣言・文字列型

'File	[MODULE1.SRC]
'$include:'TESTINC.INC'	'定数宣言ファイルインクルード
	Declare Sub Test1	'別ソースの関数を使用する為に型宣言

Main
	PDT1% = 100		'グローバル変数に値代入
	PDT2$ = "1234567890"
	Call Test1		'MODULE2.SRCのTest1関数をコール
	Wait 0, &h01	'キー入力待ち
	END

'File	[MODULE2.SRC]
'$include:'TESTINC.INC'	'定数宣言ファイルインクルード

'テスト関数の宣言
	Sub Test1
		Print "PDT1%=" ; PDT1%	'グローバル変数[PDT1%]を参照
		Print "PDT2$=" + PDT2$	'グローバル変数[PDT2$]を参照
	End Sub

■モジュール変数

ユーザが宣言する関数の外で、PRIVATE または DIMのステートメント で変数を宣言すると、モジュール変数として宣言できます。
PRIVATE 、 DIMのどちらでも効果は同じなのですが、 DIMはレジスタ変数としては宣言できない様です。
以下のソースを見てください。「MODULE2.SRC」では同じ変数名でモジュール変数を宣言しています。 「MODULE2.SRC」のモジュール変数は同じ変数名ですが、「MODULE1.SRC」とは全く異なるメモリ領域に確保されます。

'File	[MODULE1.SRC]
	PUBLIC PDT1%		'グローバル変数宣言・整数型
	PUBLIC PDT2$[256]	'グローバル変数宣言・文字列型
	Declare Sub Test1	'別ソースの関数を使用する為に型宣言

Main
	PDT1% = 100		'グローバル変数に値代入
	PDT2$ = "1234567890"
	Call Test1		'MODULE2.SRCのTest1関数をコール
	Wait 0, &h01	'キー入力待ち
	END

'File	[MODULE2.SRC]
	PRIVATE PDT1%		'モジュール変数宣言・整数型
	PRIVATE PDT2$[256]	'モジュール変数宣言・文字列型

'テスト関数の宣言
	Sub Test1
		Print "PDT1%=" ; PDT1%	'モジュール変数[PDT1%]を参照
		Print "PDT2$=" + PDT2$	'モジュール変数[PDT2$]を参照
	End Sub

これを実行すると以下の表示の様になります。 「MODULE2.SRC」のTest1関数が実行される時には、「MODULE2.SRC」内のモジュール変数として 初期化されたそれぞれの内容が表示されます。


■ローカル変数

ユーザが宣言する関数の内で、PRIVATE、DIM、STATICの各ステートメント で変数を宣言すると、ローカル変数として宣言できます。

グローバル変数やモジュール変数と同じ名前でローカル変数を宣言しても、 全く別ものとして扱われます。（全く別のメモリ領域に割り当てられます）

'File	[MODULE2.SRC]
	PRIVATE PDT1%
	PRIVATE PDT2$[256]
'テスト関数の宣言
	Sub Test1
		PRIVATE PDT1%
		PRIVATE PDT2$[256]
		PDT1% = 200		'ローカル変数に値代入
		PDT2$ = "ABC"
		Print "PDT1%=" ; PDT1%	'ローカル変数[PDT1%]を参照
		Print "PDT2$=" + PDT2$	'ローカル変数[PDT2$]を参照
	End Sub

この様に組むと、関数の中から同じ名前のモジュール変数が参照できなくなります。 そのため、通常プログラムする時にモジュール変数とローカル変数は、なるべくかぶらない様にしています。



=====
2016/04/02：の時の情報