VB.NET-TIPS などプログラミングについて

DENSOのハンディターミナルBHT-1300を使ったシステムを作成することがあったので、 ハンディターミナルの開発言語であるBHT-BASIC4.0についていろいろ載せていきたいと思います。

このBHT-BASIC4.0ですが言語としてはBASICなのですが、 最近のはやりのVisualBasic.NETとは全然違っています。
一言でいえば相当昔のBASICで、言語仕様的には30数年前の NECのPC8001やPC8801などのROM-BASICと呼ばれていたBASICに近いです。 これらのBASICは元々はMicroSoftが開発したBASICを日本のメーカが採用し ROMの中に入れていたものです。 パソコンの電源ONでいきなりBASICが走る感じになっていました。

なので、昔にBASICを触ったことが有る方ならば懐かしい感じで プログラムできるのではないでしょうか。 実際私も、昔を思い出しながら組みました。

昔語りはこの辺にしまして、BHT-BASIC4.0に話を戻します。 BHT-BASIC4.0（以降はBHT-BASICと称します）はハンディターミナルの上で動作させるためなのか、 昔のBASICよりは制約がいろいろあります。 変数の名前の長さであったり、文字列のMAX長であったりそこは ハンディターミナルなのでメモリの制約があると思われます。

それでは今回は初回なので、変数などについて記します。

■BHT-BASICのハンディターミナル内での構成

ハンディターミナルのメモリにはフラッシュメモリとＲＡＭがあり、 フラッシュメモリの中では以下の構成部分からなります。
・システムプログラム
　（BHT-BASICインタプリタ、拡張ライブラリ、拡張関数、システムドライバ等）
・ユーザプログラム
　（ユーザが作成した実行可能なプログラムファイル）
・ユーザデータファイル
　（ユーザプログラムで作成・使用されるデータファイル等）


■BHT-BASICの開発など

・BASICの文法はほぼMicroSoftのBASICと同じです。
・専用のコンパイラ・リンケージエディタで開発します。
・コンパイラ言語なので行番号は不要です。
・実行可能プログラムファイルは中間言語に変換される。
　（ファイル拡張子は PD4 ）
・開発環境はWindows7,Windows8などの32bitパソコンが必要です。
・実行プログラムをハンディターミナルに転送する通信ユニットが必要です。
　（通信ユニットにはUSBまたはRS-232Cでパソコンと接続）


■BHT-BASICの特徴など

・プログラムの1行は512文字（バイト）
・変数名に使用できるのは、英数字とピリオドのみ
・変数名は大文字と小文字の区別は無く、255文字まで
　（但し、文字列変数を表す $ 、 整数変数を表す % は文字数に含めない）
・変数のデータ型には以下の4種類がある。

データ型	型宣言文字	値の範囲
整数型	%	-32,768 ～ 32,767
長整数型	&	-2,147,483,648 ～ 2,147,483,647
実数型	無し	（ゼロ）0 （正数）0.1000000000E-64 ～ 0.9999999999E+63 （負数）-0.1000000000E-64 ～ -0.9999999999E+63
文字型	$	0文字 ～ 8192文字

文字列型の文字数のMAXが8192文字（バイト）なのは注意が必要です。 また、文字列型は他にも注意する点があるのですが、それはまた次回に記します。

今回はこの辺りまでで、終わります。
次回は、変数の宣言の仕方や、式の書き方などにします。


=====
2016/04/02：の時の情報

アプリケーションのエントリポイントとは、そのアプリケーションが開始した時に、呼び出されるメソッドのことです。

VB.NETでは、Mainメソッドがエントリポイントですが、 WindowsフォームアプリケーションプロジェクトにはMainメソッドが見当たりません。 エントリポイントであるMainメソッドは、コンパイラによって自動的に作成されます。 以下の様にプロジェクトのプロパティ設定で「スタートアップ オブジェクト」を Form1 に 設定すれば自動でMainメソッドが生成され、その中で Form1 を生成し、表示する様になっています。



しかし、 Form1 の表示前に何かをしたいことがある場合、 例えば、アプリケーションの二重起動のチェックだとか、データベースのオープン処理などがあります。 その場合には、新しいモジュールかクラスを追加し、その中に Sub Main を宣言します。 以下は Sub Main をモジュールに宣言したときの例です。
（ファイル名は MainModule.vb としました）

Module MainModule
    'アプリケーションのメイン・エントリポイント
    <STAThread()> Sub Main()
        '-----
        'メインフォームを表示する前に必要な初期処理を行う・・・
        '-----
        '例：二重起動をチェックする
        If Diagnostics.Process.GetProcessesByName(Diagnostics.Process.GetCurrentProcess.ProcessName).Length > 1 Then
            MessageBox.Show("多重起動はできません。")
            Return
        End If

        'メイン画面の表示(ここでは例としてForm1の表示)
        Dim frm As New Form1
        Application.Run(frm)

        '-----
        'メインフォームが閉じた後で必要な終了処理を行う・・・
        '-----
    End Sub
End Module

尚、この MainModule を有効にするには、プロジェクトのプロパティ設定で 以下の様にする必要があります。

「アプリケーションフレームワークを有効にする」のチェックを外し無効にします。
無効にすることで、「スタートアップ オブジェクト」のコンボボックスに  MainModule が現れますので、それを選びます。

モジュールではなく、クラスで行う場合は以下の様になります。

Public Class ClsMain
    'アプリケーションのメイン・エントリポイント
    <STAThread()> Shared Sub Main()
        '-----
        'メインフォームを表示する前に必要な初期処理を行う・・・
        '-----
        '例：二重起動をチェックする
        If Diagnostics.Process.GetProcessesByName(Diagnostics.Process.GetCurrentProcess.ProcessName).Length > 1 Then
            MessageBox.Show("多重起動はできません。")
            Return
        End If

        'メイン画面の表示(ここでは例としてForm1の表示)
        Dim frm As New Form1
        Application.Run(frm)

        '-----
        'メインフォームが閉じた後で必要な終了処理を行う・・・
        '-----
    End Sub
End Class

このソースの例では、二重起動のチェックを行っていますが、その他、データベースのオープン等 メイン画面が表示される前までに行いたい処理を、初期処理の部分に記述できます。


=====
2016/04/02：の時の情報

ADO.NET を使用した SQL-Server のテーブルをCSVファイルに出力する簡単な関数を作成してみました。

CSVファイルを作成する関数への引数は、データベース名とデータソース名と、SQL文、それとCSVファイル名とCSV内のカラムヘッダを 出力するかのフラグになります。

CSV出力処理関数内では SQL-Server への接続をオープンし、指定されたSELECT文を実行します。 SELECT文の結果の行が在れば、1行づつデータを取得します。 初回の行の処理の場合には、リーダーオブジェクトからカラム名を取得しヘッダ行を書き込みます。 その後、各データ行をCSVファイルに書き込みます。 CSVの各データは強制的にダブルクォートで囲む様にしていますので、 データ内のダブルクォートはエスケープ処理しています。

Public Class Form1
    'フォーム上に張り付けたボタンでの処理
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        SqlToCsv("TEST", ".\SQLEXPRESS12", "SELECT * FROM TEST1 ORDER BY CODE", "TEST.CSV", True)
    End Sub

    ''' <summary>指定SQL文のCSVファイル出力</summary>
    ''' <param name="Database">データベース名</param>
    ''' <param name="DataSource">データソース名</param>
    ''' <param name="SQL">SELECT文</param>
    ''' <param name="CsvFilePath">CSVファイルパス</param>
    ''' <param name="fHeader">カラムヘッダ出力指示</param>
    Private Sub SqlToCsv(ByVal Database As String, ByVal DataSource As String, ByVal SQL As String, _
                         ByVal CsvFilePath As String, ByVal fHeader As Boolean)
        'CSVファイル書込Encoding(Shift-JIS)
        Dim Enc As System.Text.Encoding = System.Text.Encoding.GetEncoding("Shift_JIS")
        'CSVファイルオープン
        Dim SWrt As New System.IO.StreamWriter(CsvFilePath, False, Enc)

        'SQL-Server接続文字列
        Dim DBConnection As String = "Persist Security Info=false;Integrated Security=SSPI;" & _
            "Database=" & Database & ";Data Source=" & DataSource & ";"
        'SQLコネクションクラス
        Dim Conn As New System.Data.SqlClient.SqlConnection(DBConnection)
        Conn.Open()
        'コマンドオブジェクト
        Dim Cmd As New System.Data.SqlClient.SqlCommand(SQL, Conn)

        'TESTデータ取得(リーダーオブジェクト)
        Dim Reader As System.Data.SqlClient.SqlDataReader = Nothing
        Reader = Cmd.ExecuteReader()
        '読込行数が存在??
        If Reader.HasRows Then
            Dim fFirst As Boolean = True
            '読込
            While Reader.Read() = True
                If fHeader = True And fFirst = True Then
                    fFirst = False
                    Dim ColName As String = ""
                    'カラム数分の処理
                    For i As Integer = 0 To Reader.FieldCount - 1
                        'カラム名取得し、ダブルクォートで囲む
                        ColName = SuroundDblQuotes(Reader.GetName(i))
                        'カラム名書込
                        SWrt.Write(ColName)
                        'カンマ書込
                        If i < Reader.FieldCount - 1 Then
                            SWrt.Write(","c)
                        End If
                    Next
                    '改行書込
                    SWrt.Write(vbCrLf)
                End If

                Dim ColData As String = ""
                For i As Integer = 0 To Reader.FieldCount - 1
                    'データ取得し、ダブルクォートで囲む
                    ColData = SuroundDblQuotes(Reader.GetValue(i).ToString())
                    'データ書込
                    SWrt.Write(ColData)
                    'カンマ書込
                    If i < Reader.FieldCount - 1 Then
                        SWrt.Write(","c)
                    End If
                Next
                '改行書込
                SWrt.Write(vbCrLf)
            End While
        End If
        'CSVファイルクローズ
        SWrt.Close()
        'クローズ
        Conn.Close()
    End Sub

    ''' <summary>文字列をダブルクォートで囲む</summary>
    Private Function SuroundDblQuotes(ByVal str As String) As String
        If str.IndexOf(""""c) > -1 Then
            '文字列をダブルクォートをダブルクォートでエスケープ
            str = str.Replace("""", """""")
        End If
        Return """" & str & """"
    End Function

尚、今回のテーブルは以下の生成文で生成しました。

CREATE TABLE TEST1 (
   CODE  VARCHAR(8) NOT NULL
  ,DATA1 VARCHAR(16)
  ,DATA2 VARCHAR(16)
  ,DATA3 VARCHAR(16)
  ,CONSTRAINT TEST1_PKC PRIMARY KEY (CODE)
);
INSERT INTO TEST1 VALUES('00000001', 'A000001', 'BBBBBB1', 'C001');
INSERT INTO TEST1 VALUES('00000002', 'A000002', 'BBBBBB2', 'C002');
INSERT INTO TEST1 VALUES('00000003', 'A000003', 'BBBBBB3', 'C003');
INSERT INTO TEST1 VALUES('00000004', 'A000004', 'BBBBBB4', 'C004');

結果的にCSVファイル内容は以下の様になります。

"CODE","DATA1","DATA2","DATA3"
"00000001","A000001","BBBBBB1","C001"
"00000002","A000002","BBBBBB2","C002"
"00000003","A000003","BBBBBB3","C003"
"00000004","A000004","BBBBBB4","C004"

=====
2016/03/22：の時の情報

エクセルでCSVファイルを読込む場合、先頭がゼロのデータが消されてしまい左寄せの様な表示になります。 例えば電場番号や商品コードなどでは、先頭にゼロが存在することは自然なことなので、 ゼロがサプレスされてしまうと不都合が在ります。

以下の様なCSVファイルをエクセルに読込んでみます。

エクセルの結果はやはり先頭ゼロが在りません。


そこで先頭ゼロのカラムデータは値をダブルコーテーションで囲んで先頭に = （イコール）を 置いてやります。 以下の様にCSVファイルを変更してやります。

エクセルの結果は先頭ゼロが表示される様になりました。

上図のセルの値からも分かるように、値が ="0012345" とCSVファイルの値そのものになるので 注意が必要です。これをそのまま印刷しても 0012345 とちゃんと表示されます。


=====
2016/03/25：の時の情報

マスタのメンテテンス用プログラムとしては、1個のウインドウでいろんな項目を入力するのですが、 基本的には項目名とそれに対応するデータ入力コントロールとしてテキストボックス等を設置します。
このテキストボックスには入力の書式や、キーデータの選択等を自分で組んでやる必要があります。 市販の入力用コントロールを使えばいいのですが、自分で組むと結構大変です。
そこで、SPREADの出番なのですが、SPREAD自身には既に入力コントロールが備わっています。 これを使わない手はありません。SPREADなので表形式になってしまいますが、 この形が許されるのであれば、SPREADを使っていいのではと思います。

SPREADには、数値セルタイプとして CurrencyCellType , NumberCellType がありますが、 今回は NumberCellType を使って数値用のメンテナンスを行う場合を想定した例を紹介します。

画面の表示は以下の様になります。

以下の今回のソースを示しますが、フォームのロード時に全ての数値セルの CellType を設定しています。 尚、最後のコード的なセルは、通常では編集入力後の表示で先頭ゼロを行う様に、  NumberCellType を拡張したクラスを定義しています。
また、セルの編集時には背景色と文字色を変更して入力を分かりやすくしています。

Imports FarPoint.Win.Spread.CellType
Public Class Form1
    'フォームロード時イベントで各数値セルの初期化
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim NumCell As New NumberCellType
        '【ZZ9】
        With NumCell
            .DecimalPlaces = 0
            .MaximumValue = 999
            .MinimumValue = 0
        End With
        FpSpread1.ActiveSheet.Cells(0, 1).CellType = NumCell

        '【ZZ9.99】
        NumCell = New NumberCellType
        With NumCell
            .DecimalPlaces = 2
            .MaximumValue = 999.99
            .MinimumValue = 0
        End With
        FpSpread1.ActiveSheet.Cells(1, 1).CellType = NumCell

        '【-ZZ9～ZZ9】
        NumCell = New NumberCellType
        With NumCell
            .DecimalPlaces = 0
            .MaximumValue = 999
            .MinimumValue = -999
            .NegativeRed = True
        End With
        FpSpread1.ActiveSheet.Cells(2, 1).CellType = NumCell

        '【-ZZ9.99～ZZ9.99】
        NumCell = New NumberCellType
        With NumCell
            .DecimalPlaces = 2
            .MaximumValue = 999.99
            .MinimumValue = -999.99
            .NegativeRed = True
        End With
        FpSpread1.ActiveSheet.Cells(3, 1).CellType = NumCell

        '【-ZZ,ZZ9～ZZ,ZZ9】
        NumCell = New NumberCellType
        With NumCell
            .DecimalPlaces = 0
            .MaximumValue = 99999
            .MinimumValue = -99999
            .NegativeRed = True
            .Separator = ","
            .ShowSeparator = True
        End With
        FpSpread1.ActiveSheet.Cells(4, 1).CellType = NumCell

        '【CODE 99999】
        Dim CdCell = New CodeCellType
        With CdCell
            .MaximumValue = 99999
            .MinimumValue = 0
        End With
        FpSpread1.ActiveSheet.Cells(5, 1).CellType = CdCell
    End Sub

    '編集中に背景色と文字色を変える
    Private Sub FpSpread1_EditModeOn(sender As Object, e As EventArgs) Handles FpSpread1.EditModeOn
        CType(FpSpread1.EditingControl, GeneralEditor).BackColor = Color.AntiqueWhite
        CType(FpSpread1.EditingControl, GeneralEditor).ForeColor = Color.Blue
    End Sub

    '入力データの取得・表示
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim str As String = ""
        str &= "ZZ9 : " & Me.FpSpread1.ActiveSheet.GetValue(0, 1) & vbCrLf
        str &= "ZZ9.99 : " & Me.FpSpread1.ActiveSheet.GetValue(1, 1) & vbCrLf
        str &= "-ZZ9～ZZ9 : " & Me.FpSpread1.ActiveSheet.GetValue(2, 1) & vbCrLf
        str &= "-ZZ9.99～ZZ9.99 : " & Me.FpSpread1.ActiveSheet.GetValue(3, 1) & vbCrLf
        str &= "-ZZ,ZZ9～ZZ,ZZ9 : " & Me.FpSpread1.ActiveSheet.GetValue(4, 1) & vbCrLf
        str &= "CODE 99999 : " & Me.FpSpread1.ActiveSheet.GetValue(5, 1) & vbCrLf
        MsgBox(str, "数値入力テスト")
    End Sub
End Class

'【CODE用カスタムセルクラス】
Public Class CodeCellType
    Inherits FarPoint.Win.Spread.CellType.NumberCellType

    Public Sub New()
        MyBase.New()
        Me.DecimalPlaces = 0
    End Sub

    '編集を抜ける時に先頭ゼロ付きで表示
    Public Overrides Function Format(ByVal obj As Object) As String
        Dim Val As Decimal = Convert.ToDecimal(obj)
        Dim Len As Integer = Me.MaximumValue.ToString.Length
        Return Val.ToString(New String("0"c, Len))
    End Function
End Class

下図は、「Button1」をクリックした時の表示です。


■SPREADをコントロールを何個も設置

SPREADの表形式が気に入らないのであれば、テキストボックスを何個も設置する様に 1セルしかないSPREADを個別に設置し、それぞれのSPREADのセルにCellTypeを設定してやれば テキストボックス的に使えます。
この方法だと、SPREADコントロールを何個も設置するのでプログラムの動きが重くなるかも しれませんが、意外と使える方法だと思いますが、如何でしょうか？


=====
2016/03/18：の時の情報