VB.NET-TIPS などプログラミングについて

2019/08/26

EXEファイルの実行フォルダが必要になることはよくあります。フォルダを取得して、そこからの相対フォルダ参照で、データフォルダなどを作成・参照を行ったりしますので、その方法について示します。

まず最初は通常のWindowsフォームを持っているEXEファイルに付いてです。

WindowsフォームでのEXEファイル取得

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim strPath As String = ""

    'System.Windows.Forms.Application のSharedプロパティ「ExecutablePath」を参照
    '　アプリケーションを開始した実行可能ファイルのパスを、ファイル名を含めて取得します。
    strPath = System.Windows.Forms.Application.ExecutablePath
    Console.WriteLine("ExecutablePathdでのExeフルパス：[{0}]", strPath)

    '因みに、System.Windows.Forms.Application のSharedプロパティ「StartupPath」を参照
    '　アプリケーションを開始した実行可能ファイルのファイル名を含まないパス取得します。
    strPath = System.Windows.Forms.Application.StartupPath
    Console.WriteLine("StartupPathでのExeフルパス：[{0}]", strPath)
End Sub

実行結果は以下の様になります。

ExecutablePathdでのExeフルパス：[C:¥TestSrv¥BlogTest¥BlogTest¥bin¥Debug¥BlogTest.EXE]
StartupPathでのExeフルパス：[C:¥TestSrv¥BlogTest¥BlogTest¥bin¥Debug]

コンソールアプリの場合にはこれは使えないので、以下の様に自分自身のアセンブリを取得し、そのLocationプロパティを取得することでEXEのフルパスが取得できます。

GetExecutingAssembly().Location でのEXEファイル取得

Module MdlMainPath
    'Main関数
    Sub Main()
        Dim strPath As String = ""
        'GetExecutingAssembly().Locationでの実行ファイルのパスを取得する
        strPath = System.Reflection.Assembly.GetExecutingAssembly().Location
        Console.WriteLine("GetExecutingAssembly().LocationでのExeフルパス：[{0}]", strPath)

        'パスから実行フォルダのみを取り出す
        strPath = System.IO.Path.GetDirectoryName(strPath)
        Console.WriteLine("GetExecutingAssembly().LocationでのExeフォルダ：[{0}]", strPath)
    End Sub
End Module

実行結果は以下の様になります。

GetExecutingAssembly().LocationでのExeフルパス：[C:¥TestSrv¥BlogTest¥BlogTest¥bin¥Debug¥BlogTest.exe]
GetExecutingAssembly().LocationでのExeフォルダ：[C:¥TestSrv¥BlogTest¥BlogTest¥bin¥Debug]

MidB 関数

''' 
''' 開始位置、バイト指定による文字列切出・Mid関数
''' 
''' <param name="astrSrc">対象文字列</param>
''' <param name="aintStart">開始位置(先頭1から)</param>
''' <param name="aintLen">切出しバイト数</param>
''' 切出し文字列
Private Function MidB(ByVal astrSrc As String, 
                      ByVal aintStart As Integer,
                      ByVal aintLen As Integer) As String
    Try
        '開始を「0」からの指標
        Dim intStart As Integer = aintStart - 1
        '開始が１より小さい場合は空文字を返す
        If intStart < 0 Then
            Return ""
        End If
        'Shift-JISでエンコーディングしてバイト配列に分解
        Dim objEnc As System.Text.Encoding =
                      System.Text.Encoding.GetEncoding("Shift_JIS")
        Dim arrBytes As Byte() = objEnc.GetBytes(astrSrc)
        '開始がバイト配列より大きい場合は空文字を返す
        If intStart > arrBytes.Length - 1 Then
            Return ""
        End If

        '取り出しバイト数
        Dim intLen As Integer = aintLen
        If (intStart + aintLen) > (arrBytes.Length - 1) Then
            intLen = arrBytes.Length - intStart
        End If

        '先頭から見て指定位置の直前までを切り出す
        Dim strTemp As String = objEnc.GetString(arrBytes, 0, intStart)
        If strTemp.EndsWith(ControlChars.NullChar) Or strTemp.EndsWith("・") Then
            '最後の文字が漢字の左半分の場合、切出の先頭は泣き別れになる
            intStart += 1   '開始位置を右へ
            intLen -= 1     '切出バイト数を1個少なくする
        End If

        '修正位置とバイト数で切り出す
        strTemp = objEnc.GetString(arrBytes, intStart, intLen)
        If strTemp.EndsWith(ControlChars.NullChar) Or strTemp.EndsWith("・") Then
            '最後の文字が漢字の左半分の場合、泣き別れになる
            intLen -= 1     '切出バイト数をさらに1個少なくする
        End If

        '文字列を返す
        Return objEnc.GetString(arrBytes, intStart, intLen)

    Catch ex As Exception
        Return ""
    End Try
End Function

以前の VB の Mid$ では第3引数が無く、開始位置から右側を全て返す関数がありましたので、同じ関数名で引数の数が異なる関数を以下に記します。

MidB 関数（開始位置以降の切出し）

''' 
''' 開始位置以降の文字列切出・Mid関数
''' 
''' <param name="astrSrc">対象文字列</param>
''' <param name="aintStart">開始位置(先頭1から)</param>
''' 切出し文字列
Private Function MidB(ByVal astrSrc As String, ByVal aintStart As Integer) As String
    Try
        '開始を「0」からの指標
        Dim intStart As Integer = aintStart - 1
        '開始が１より小さい場合は空文字を返す
        If intStart < 0 Then
            Return ""
        End If
        'Shift-JISでエンコーディングしてバイト配列に分解
        Dim objEnc As System.Text.Encoding =
                      System.Text.Encoding.GetEncoding("Shift_JIS")
        Dim arrBytes As Byte() = objEnc.GetBytes(astrSrc)
        '開始がバイト配列より大きい場合は空文字を返す
        If intStart > arrBytes.Length - 1 Then
            Return ""
        End If

        '実際の処理は上記の関数をコール
        Return MidB(astrSrc, aintStart, arrBytes.Length - aintStart + 1)

    Catch ex As Exception
        Return ""
    End Try
End Function

さらに、文字列の左側から指定バイト数を切り出す LeftB 関数、文字列の右側から指定バイト数を切り出す RightB 関数を記します。この2個の関数は最初の MidB 関数を利用しています。

LeftB 関数 , RightB 関数

''' 
''' バイト数指定による文字列の左側切出し・Left関数
''' 
''' <param name="astrSrc">対象文字列</param>
''' <param name="aintLen">左側切出しバイト数</param>
''' 切出し文字列
Private Function LeftB(ByVal astrSrc As String, ByVal aintLen As Integer) As String
    '先頭から指定バイト数を切り出す
    Return MidB(astrSrc, 1, aintLen)
End Function

''' 
''' バイト数指定による文字列の右側切出し・Right関数
''' 
''' <param name="astrSrc">対象文字列</param>
''' <param name="aintLen">右側切出しバイト数</param>
''' 切出し文字列
Private Function RightB(ByVal astrSrc As String, ByVal aintLen As Integer) As String
    'Shift-JISでエンコーディングしてバイト配列に分解
    Dim objEnc As System.Text.Encoding = System.Text.Encoding.GetEncoding("Shift_JIS")
    Dim arrBytes As Byte() = objEnc.GetBytes(astrSrc)
    'バイト数がバイト配列の個数より多い場合は、対象文字列そのまま返す
    If aintLen >= arrBytes.Length Then
        Return astrSrc
    End If
    '開始位置
    Dim intStart As Integer = arrBytes.Length - aintLen + 1
    '先頭から指定バイト数を切り出す
    Return MidB(astrSrc, intStart, aintLen)
End Function

これらの関数を実行する例を以下に記します。これはフォームにボタンを設置し、クリックイベント時に、各関数の処理を行い結果をデバッグ用の出力ウインドウに表示しています。

    Private Sub btnStringCut_Click(sender As Object, e As EventArgs) Handles btnStringCut.Click
        '表示
        Dim strSrc As String = "あいうえお"
        Dim i As Integer

        '引数が3個ある MidB 関数
        Dim nCut As Integer = 6
        For i = 0 To 10
            Dim strDes As String = MidB(strSrc, i, nCut)
            Console.WriteLine("MidB(""{0}"", {1}, {2}) : /{3}/", strSrc, i, nCut, strDes)
        Next

        '引数が2個の MidB 関数
        For i = 0 To 10
            Dim strDes As String = MidB(strSrc, i)
            Console.WriteLine("MidB(""{0}"", {1}) : /{2}/", strSrc, i, strDes)
        Next

        'LeftB 関数
        For i = 0 To 10
            Dim strDes As String = LeftB(strSrc, i)
            Console.WriteLine("LeftB(""{0}"", {1}) : /{2}/", strSrc, i, strDes)
        Next

        'RightB 関数
        For i = 1 To 11
            Dim strDes As String = RightB(strSrc, i)
            Console.WriteLine("RightB(""{0}"", {1}) : /{2}/", strSrc, i, strDes)
        Next
    End Sub

結果の表示は以下の通りです。

MidB("あいうえお", 0, 6) : //
MidB("あいうえお", 1, 6) : /あいう/
MidB("あいうえお", 2, 6) : /いう/
MidB("あいうえお", 3, 6) : /いうえ/
MidB("あいうえお", 4, 6) : /うえ/
MidB("あいうえお", 5, 6) : /うえお/
MidB("あいうえお", 6, 6) : /えお/
MidB("あいうえお", 7, 6) : /えお/
MidB("あいうえお", 8, 6) : /お/
MidB("あいうえお", 9, 6) : /お/
MidB("あいうえお", 10, 6) : //
MidB("あいうえお", 0) : //
MidB("あいうえお", 1) : /あいうえお/
MidB("あいうえお", 2) : /いうえお/
MidB("あいうえお", 3) : /いうえお/
MidB("あいうえお", 4) : /うえお/
MidB("あいうえお", 5) : /うえお/
MidB("あいうえお", 6) : /えお/
MidB("あいうえお", 7) : /えお/
MidB("あいうえお", 8) : /お/
MidB("あいうえお", 9) : /お/
MidB("あいうえお", 10) : //
LeftB("あいうえお", 0) : //
LeftB("あいうえお", 1) : //
LeftB("あいうえお", 2) : /あ/
LeftB("あいうえお", 3) : /あ/
LeftB("あいうえお", 4) : /あい/
LeftB("あいうえお", 5) : /あい/
LeftB("あいうえお", 6) : /あいう/
LeftB("あいうえお", 7) : /あいう/
LeftB("あいうえお", 8) : /あいうえ/
LeftB("あいうえお", 9) : /あいうえ/
LeftB("あいうえお", 10) : /あいうえお/
RightB("あいうえお", 1) : //
RightB("あいうえお", 2) : /お/
RightB("あいうえお", 3) : /お/
RightB("あいうえお", 4) : /えお/
RightB("あいうえお", 5) : /えお/
RightB("あいうえお", 6) : /うえお/
RightB("あいうえお", 7) : /うえお/
RightB("あいうえお", 8) : /いうえお/
RightB("あいうえお", 9) : /いうえお/
RightB("あいうえお", 10) : /あいうえお/
RightB("あいうえお", 11) : /あいうえお/

VB.NET-TIPS などプログラミングについて

WindowsフォームでのEXEファイル取得

GetExecutingAssembly().Location でのEXEファイル取得

関連する記事

MidB 関数

MidB 関数（開始位置以降の切出し）

LeftB 関数 , RightB 関数

関連する記事

OracleSQL入門

関連する記事

■ブロック領域を表示・非表示にする