その他｜VB.NET-TIPS などプログラミングについて

■その他

[2019/10/28] コレクション「Dictionary」の使い方について (No.133)
[2019/10/11] コレクション「List」と配列の相互変換について (No.131)
[2019/10/09] コレクション「List」の使い方について (No.130)
[2019/10/01] オブジェクト型から数値型への変換（TryParse） (No.126)
[2019/09/05] 金額計算（会計処理など）は Decimal 型で、科学計算には Double 型を使用する (No.123)

≪ [1] [2] [3] [4] [5] [6] [7] [8] ≫

2019/10/28

コレクション「Dictionary」の使い方について

コレクションクラスの中に Dictionary がありますが、以前の記事の List とは異なり、各要素にキー（索引）を持ちます。そのキーを用いて要素にアクセスする連想配列の様なものです。 Dictionary クラスの定義は以下の様になっています。

■Dictionaryの宣言
Public Class Dictionary(Of TKey, TValue)
概要:
キーと値のコレクションを表します。
型パラメーター:
　TKey  : ディクショナリ内のキーの型。
　TValue: ディクショナリ内の値の型。

それでは Dictionary の使い方について順を追って説明したいと思います。

簡単な Dictionary の宣言と使い方
Dictionary の繰り返し処理は For Each で行う
Dictionary の初期化
Dictionary の定義と各メソッド等について

■簡単な Dictionary の宣言と使い方

以下のソースを見て下さい。
最初に Dictionary を生成し Add メソッドで新しく要素をキーと共に、3個追加します。その後、追加したキーで要素を取得します。尚、キーの指定で追加していないキーでの要素の取得を試みます。（最後の取得でエラーが発生するはずです）

Public Class frmDictionary

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ' Dictionaryの生成
        Dim dic As New Dictionary(Of String, String)
        ' 要素の追加
        dic.Add("A", "America")
        dic.Add("C", "China")
        dic.Add("J", "Japan")
        ' 要素の取得(KEY="A")
        Console.WriteLine("KEY:{0} のDictionaryの要素：{1}", "A", dic.Item("A"))
        ' 要素の取得(KEY="J")
        Console.WriteLine("KEY:{0} のDictionaryの要素：{1}", "J", dic.Item("J"))
        ' 要素に存在しないKEYの指定
        Console.WriteLine("KEY:{0} のDictionaryの要素：{1}", "X", dic.Item("X"))
    End Sub
End Class

実行結果としてコンソールには以下様に表示されますが、最後の取得で下図の様にエラーが発生します。

KEY:A のDictionaryの要素：America
KEY:J のDictionaryの要素：Japan

■Dictionary の繰り返し処理は For Each で行う

上記のソースでは Dictionary の要素を Item プロパティで取得しましたが、 For Each 文を使えば Dictionary の要素を順次取得できます。そこで上記のソースを以下の様に変更し実行してみます。

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ' Dictionaryの生成
        Dim dic As New Dictionary(Of String, String)
        ' 要素の追加
        dic.Add("A", "America")
        dic.Add("C", "China")
        dic.Add("J", "Japan")
        ' For Each での順次処理
        For Each item In dic
            ' 要素
            Console.WriteLine("KEY:{0} のDictionaryの要素：{1}", item.Key, item.Value)
        Next
    End Sub

結果は以下の様になります。ここで For Each の item 変数なのですが、これは KeyValuePair 型になります。これ自身は Structure なのでそのプロパティにアクセスしてキー（Key）と値（Value）を取得します。

KEY:A のDictionaryの要素：America
KEY:C のDictionaryの要素：China
KEY:J のDictionaryの要素：Japan

ここで KeyValuePair 型についてですが、VBでの内部では以下の様に宣言されています。

■KeyValuePairの宣言(一般的な宣言)
Public Structure KeyValuePair(Of TKey, TValue)

この宣言は一般的なものであり、それぞれの Dictionary によって TKey、TValue の部分のデータ型が変わります。

■今回の例のKeyValuePairの宣言について
Public Structure KeyValuePair(Of String, String)

依って、上記のソースの9行目は厳格に宣言するのであれば以下の様にします。

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ' Dictionaryの生成
        Dim dic As New Dictionary(Of String, String)
        ' 要素の追加
        dic.Add("A", "America")
        dic.Add("C", "China")
        dic.Add("J", "Japan")
        ' For Each での順次処理
        For Each item As KeyValuePair(Of String, String) In dic
            ' 要素
            Console.WriteLine("KEY:{0} のDictionaryの要素：{1}", item.Key, item.Value)
        Next
    End Sub

尚 Dictionary にはキー及び値のみのコレクションを持っていますので、それぞれを別々に For Each 処理できます。

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ' Dictionaryの生成
        Dim dic As New Dictionary(Of String, String)
        ' 要素の追加
        dic.Add("A", "America")
        dic.Add("C", "China")
        dic.Add("J", "Japan")
        ' For Each でのキーの順次処理
        For Each strKey As String In dic.Keys
            ' 要素
            Console.WriteLine("KEY:{0}", strKey)
        Next
        ' For Each での値の順次処理
        For Each strVal As String In dic.Values
            ' 要素
            Console.WriteLine("Dictionaryの要素：{0}", strVal)
        Next
    End Sub

結果は以下の様になります。

KEY:A
KEY:C
KEY:J
Dictionaryの要素：America
Dictionaryの要素：China
Dictionaryの要素：Japan

■Dictionary の初期化

Dictionary の生成とで一緒に初期化ができます。生成の宣言の後に、From で繋ぎ {}(中括弧) で要素を ,(カンマ) で区切って記述します。要素は { キー , 値 } の様に「キー」「値」をセットにします。

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ' Dictionaryの生成
        Dim dic As New Dictionary(Of String, String) From _
                                {{"A", "America"}, {"C", "China"}, {"J", "Japan"}}
        ' For Each での順次処理
        For Each item In dic
            ' 要素
            Console.WriteLine("KEY:{0} のDictionaryの要素：{1}", item.Key, item.Value)
        Next
    End Sub

実行結果は以下の通りです。

KEY:A のDictionaryの要素：America
KEY:C のDictionaryの要素：China
KEY:J のDictionaryの要素：Japan

■Dictionary の各メソッド・プロパティ等について

メソッド or プロパティ	書式	説明
Add	Add(key As TKey, value As TValue) key：追加する要素のキー value：追加する要素の値(参照型の場合、null の値を使用可)	指定したキーと値をディクショナリに追加します
Clear	Clear()	Dictionary(Of TKey, TValue) からすべてのキーと値を削除します
ContainsKey	ContainsKey(key As TKey) As Boolean （プロパティ） key：Dictionary(Of TKey, TValue) 内で検索されるキー戻り値：指定したキーを持つ要素が Dictionary(Of TKey, TValue) に存在する場合は true,それ以外は false	指定したキーが Dictionary(Of TKey, TValue) での存在を確認します
Count	Count As Integer （これはプロパティ）	Dictionary(Of T) に存在する要素の数を取得します
Item	Item(key As TKey) As TValue （プロパティ） key：取得または設定する値のキー戻り値：指定したキーに関連付けられている値指定したキーが見つからなかった場合 get 操作は KeyNotFoundException をスロー set 操作は指定したキーを持つ新しい要素を作成例外：ArgumentNullException 　index が 0 未満,または Dictionary(Of T).Count 以上例外：KeyNotFoundException 　プロパティが取得されたが,コレクション内に key が存在無し	指定したキーに関連付けられている値を取得または設定します
Keys	Keys As Dictionary(Of TKey, TValue).KeyCollection （プロパティ）戻り値： Dictionary(Of TKey, TValue) 内のキーを格納しているDictionary(Of TKey, TValue).KeyCollection	Dictionary(Of TKey, TValue) 内のキーを格納しているコレクションを取得します
Values	Values As Dictionary(Of TKey, TValue).ValueCollection （プロパティ）戻り値： Dictionary(Of TKey, TValue) 内の値を格納しているDictionary(Of TKey, TValue).KeyCollection	Dictionary(Of TKey, TValue) 内の値を格納しているコレクションを取得します
Remove	Remove(key As TKey) As Boolean key：削除する要素のキー戻り値：要素が見つかり、正常に削除された場合は true, それ以外の場合は false key が Dictionary(Of TKey, TValue) に存在しない場合,false	指定したキーを持つ値を Dictionary(Of TKey, TValue) から削除します

上記のメソッド等を順を追って説明します。

Clear と ContainsKey と Count について
IndexOf コレクション要素のインデックスの検索
Insert 指定したインデックスの位置に要素を挿入
Remove RemoveAt RemoveRange 要素の削除

■Clear と ContainsKey と Count について

先ず Dictionary を生成しDictionaryの件数を Count プロパティで取得し、その後 Clear で Dictionary の要素を全て削除します。尚、 ContainsKey プロパティで Clear 前後でキーの存在確認を行います。

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ' Dictionaryの生成
        Dim dic As New Dictionary(Of String, String) From _
                                {{"A", "America"}, {"C", "China"}, {"J", "Japan"}}
        ' Dictionaryの件数
        Console.WriteLine("Dictionaryの件数：{0}", dic.Count)
        ' ContainsKey確認
        Dim key As String = "J"
        Console.WriteLine("キー[{0}]の存在確認：{1}", key, dic.ContainsKey(key))
        ' Clear
        Console.WriteLine("=== Clear ===")
        dic.Clear()
        Console.WriteLine("Dictionaryの件数：{0}", dic.Count)
        ' ContainsKey確認
        Console.WriteLine("キー[{0}]の存在確認：{1}", key, dic.ContainsKey(key))
    End Sub

実行結果は以下の通りです。また Clear 後は件数が「0」になります。

Dictionaryの件数：3
キー[J]の存在確認：True
=== Clear ===
Dictionaryの件数：0
キー[J]の存在確認：False

■IndexOf コレクション要素のインデックスの検索

先ず Dictionary を生成しその要素の値指定でインデックスを IndexOf 関数で取得します。
その後、検索開始インデックスを指定する IndexOf での例を以下に示します。

    Private Sub btnDictionary_Click(sender As Object, e As EventArgs) Handles btnDictionary.Click
        Dim i As Integer = 0

        ' Dictionaryの生成（初期化）                   0   1    2     3      4  5   6    7
        Dim list As New Dictionary(Of Integer) From {1, 10, 100, 1000, 10000, 2, 20, 200}

        ' IndexOf(item As T)
        Console.WriteLine("=== IndexOf(item As T) ===")
        i = list.IndexOf(1000)
        Console.WriteLine("itemが「{0}」のインデックス：{1}", 1000, i)
        i = list.IndexOf(1500)
        Console.WriteLine("itemが「{0}」のインデックス：{1}", 1500, i)

        ' IndexOf(item As T, index As Integer)
        Console.WriteLine("=== IndexOf(item As T, index As Integer) ===")
        i = list.IndexOf(20, 4)
        Console.WriteLine("itemが「{0}」をインデックス「{1}」から検索した結果のインデックス：{2}", 20, 4, i)
        i = list.IndexOf(1000, 4)
        Console.WriteLine("itemが「{0}」をインデックス「{1}」から検索した結果のインデックス：{2}", 1000, 4, i)
    End Sub

実行結果は以下の通りです。
要素の値指定のみの IndexOf では先頭から検索する為「1000」の値の場合はインデックス「3」が返り、「1500」の値の場合は Dictionary の要素に存在しないので「-1」が返ります。
検索開始インデックスを指定する IndexOf では開始インデックスを「4」とし、検索要素値「20」の場合は「6」が返り、検索要素値「1000」の場合はインデックスを「4」以降には値が存在しないので「-1」が返ります。

=== IndexOf(item As T) ===
itemが「1000」のインデックス：3
itemが「1500」のインデックス：-1
=== IndexOf(item As T, index As Integer) ===
itemが「20」をインデックス「4」から検索した結果のインデックス：6
itemが「1000」をインデックス「4」から検索した結果のインデックス：-1

■Insert 指定したインデックスの位置に要素を挿入

先ず Dictionary を生成しインデックス「5」の位置に「300」を挿入します。
その後、存在しないインデックス「10」の位置に挿入処理を行いエラーが発生することを確認します。

    Private Sub btnDictionary_Click(sender As Object, e As EventArgs) Handles btnDictionary.Click
        Dim i As Integer = 0

        ' Dictionaryの生成（初期化）
        Dim list As New Dictionary(Of Integer) From {1, 10, 100, 1000, 10000, 2, 20, 200}

        ' Insert(index As Integer, item As T)
        Console.WriteLine("=== Insert(index As Integer, item As T) ===")
        list.Insert(5, 300) 'インデックス「5」の位置に「300」を挿入
        i = 0
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したDictionaryの要素：{1}", i, nVal)
            i += 1              '指標＋１
        Next
        Try
            ' エラーが必ず発生
            list.Insert(10, 900) 'インデックス「10」の位置に「900」を挿入
        Catch ex As Exception
            Console.WriteLine("Insertエラー：{0}", ex.Message)
        End Try
    End Sub

実行結果は以下の通りです。
インデックス「5」の位置に「300」が挿入され、それ以降は順次繰り下がったことがわかります。
また、インデックス「10」の位置での挿入処理はエラーが返されています。

=== Insert(index As Integer, item As T) ===
0番目に取得したDictionaryの要素：1
1番目に取得したDictionaryの要素：10
2番目に取得したDictionaryの要素：100
3番目に取得したDictionaryの要素：1000
4番目に取得したDictionaryの要素：10000
5番目に取得したDictionaryの要素：300
6番目に取得したDictionaryの要素：2
7番目に取得したDictionaryの要素：20
8番目に取得したDictionaryの要素：200
Insertエラー：インデックスは一覧の範囲内になければなりません。
パラメーター名:index

■Remove RemoveAt RemoveRange 要素の削除

先ず Dictionary を生成し Remove で値が「300」の要素を削除します。2回行うことで異なる結果が返ってくるはずです。その後 RemoveAt でインデックス「5」の位置を削除処理を行い一覧確認します。さらに存在しないインデックス「10」の位置を削除処理し、エラー発生を確認します。
その後 RemoveRange でインデックス「3」の位置から「2」個の要素を削除処理を行い一覧確認します。さらにインデックス「3」の位置から存在しない個数の「5」で削除処理し、エラー発生を確認します。

    Private Sub btnDictionary_Click(sender As Object, e As EventArgs) Handles btnDictionary.Click
        Dim i As Integer = 0

        ' Dictionaryの生成（初期化）
        Dim list As New Dictionary(Of Integer) From {1, 10, 100, 1000, 10000, 300, 2, 20, 200}

        Dim blnRet As Boolean
        ' Remove(item As T)
        Console.WriteLine("=== Remove(item As T) ===")
        blnRet = list.Remove(300)
        Console.WriteLine("itemが「{0}」削除：{1}", 300, blnRet)
        blnRet = list.Remove(300)
        Console.WriteLine("itemが「{0}」削除：{1}", 300, blnRet)

        ' RemoveAt(index As Integer)
        Console.WriteLine("=== RemoveAt(index As Integer) ===")
        list.RemoveAt(5)
        Console.WriteLine("インデックス「{0}」の要素を削除", 5)
        i = 0
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したDictionaryの要素：{1}", i, nVal)
            i += 1              '指標＋１
        Next
        Try
            ' エラーが必ず発生
            list.RemoveAt(10) 'インデックス「10」の位置の要素削除
        Catch ex As Exception
            Console.WriteLine("RemoveAtエラー：{0}", ex.Message)
        End Try

        ' RemoveRange(index As Integer, count As Integer)
        Console.WriteLine("=== RemoveRange(index As Integer, count As Integer) ===")
        list.RemoveRange(3, 2)
        Console.WriteLine("インデックス「{0}」から「{1}」個の要素を削除", 3, 2)
        i = 0
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したDictionaryの要素：{1}", i, nVal)
            i += 1              '指標＋１
        Next
        Try
            ' エラーが必ず発生
            list.RemoveRange(3, 5)
        Catch ex As Exception
            Console.WriteLine("RemoveRangeエラー：{0}", ex.Message)
        End Try
    End Sub

実行結果は以下の通りです。

=== Remove(item As T) ===
itemが「300」削除：True
itemが「300」削除：False
=== RemoveAt(index As Integer) ===
インデックス「5」の要素を削除
0番目に取得したDictionaryの要素：1
1番目に取得したDictionaryの要素：10
2番目に取得したDictionaryの要素：100
3番目に取得したDictionaryの要素：1000
4番目に取得したDictionaryの要素：10000
5番目に取得したDictionaryの要素：20
6番目に取得したDictionaryの要素：200
RemoveAtエラー：インデックスが範囲を超えています。負でない値で、コレクションのサイズよりも小さくなければなりません。
パラメーター名:index
=== RemoveRange(index As Integer, count As Integer) ===
インデックス「5」から「2」個の要素を削除
0番目に取得したDictionaryの要素：1
1番目に取得したDictionaryの要素：10
2番目に取得したDictionaryの要素：100
3番目に取得したDictionaryの要素：20
4番目に取得したDictionaryの要素：200
RemoveRangeエラー：配列のオフセットおよび長さが範囲を超えているか、カウンターがソース コレクションのインデックスから最後までの要素の数より大きい値です。

■List から配列への変換（ToArray, CopyTo）

変換を行う為に List の ToArray 関数及び CopyTo メソッドを使いますが、それぞれの定義は以下の様になります。

メソッド or 関数	書式	説明
ToArray	ToArray() As T() 戻り値：List(Of T) の要素のコピーを格納する配列	List(Of T) の要素を新しい配列にコピーします
CopyTo	CopyTo(array() As T) array：List(Of T) から要素がコピーされる 1次元の System.Array 　　　　System.Array には、0 から始まるインデックス番号が必要です	List(Of T) 全体を互換性のある1次元の先頭から配列にコピーします
CopyTo	CopyTo(array() As T, index As Integer) array：List(Of T) から要素がコピーされる 1次元の System.Array index：コピーの開始位置で、array 内の 0 から始まるインデックス例外：ArgumentOutOfRangeException 　index が 0 未満例外：ArgumentException 　List(Of T) の要素数が index からコピー先の array の　末尾までに格納できる数を超えています	List(Of T) 全体を互換性のある1次元の指定したインデックスから配列にコピーします

以下のソースを見て下さい。ToArray, CopyTo の例を記します。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        Dim i As Integer = 0
        ' Listの生成（初期化）
        Dim list As New List(Of Integer) From {1, 10, 100, 1000, 10000}
        Dim list2 As New List(Of Integer) From {2, 20, 200}

        ' 配列へ変換
        Dim arr() As Integer
        Console.WriteLine("=== ToArray ===")
        arr = list.ToArray
        For i = 0 To UBound(arr)
            Console.WriteLine("arr({0})の要素：{1}", i, arr(i))
        Next

        ' 配列へのコピー
        Console.WriteLine("=== CopyTo ===")
        list2.CopyTo(arr)
        For i = 0 To UBound(arr)
            Console.WriteLine("arr({0})の要素：{1}", i, arr(i))
        Next

        ' 最初に少ないListデータを配列へ変換
        arr = list2.ToArray
        Try
            ' エラーの起きる配列へのコピー
            list.CopyTo(arr)
        Catch ex As Exception
            Console.WriteLine("CopyToエラー：{0}", ex.Message)
        End Try

        ' 再度listから変換
        arr = list.ToArray
        ' インデックスを指定して配列へのコピー
        Console.WriteLine("=== CopyTo(index) ===")
        list2.CopyTo(arr, 2)
        For i = 0 To UBound(arr)
            Console.WriteLine("arr({0})の要素：{1}", i, arr(i))
        Next
    End Sub

実行結果がコンソールには以下様に表示されます。
10行目の ToArray 関数により「list」から「arr」に変換され、要素がコピーされていることが分かります。 17行目の CopyTo メソッドにより「list2」から「arr」の先頭から要素が上書きコピーされていることが分かります。「arr」の要素(3),(4)はそのままになっています。
再度「list2」から「arr」に変換し、26行目で要素数の多い「list」を上書きコピーさせています。「arr」は要素数が足りないので、エラーが発生します。
再度「list」から「arr」に変換し、35行目で2番目の要素から「list2」を上書きコピーさせています。

=== ToArray ===
arr(0)の要素：1
arr(1)の要素：10
arr(2)の要素：100
arr(3)の要素：1000
arr(4)の要素：10000
=== CopyTo ===
arr(0)の要素：2
arr(1)の要素：20
arr(2)の要素：200
arr(3)の要素：1000
arr(4)の要素：10000
CopyToエラー：ターゲット配列の長さが足りません。destIndex、長さ、および配列の最小値を確認してください。
=== CopyTo(index) ===
arr(0)の要素：1
arr(1)の要素：10
arr(2)の要素：2
arr(3)の要素：20
arr(4)の要素：200

■List の生成(New)で配列指定

List を生成する時に配列を指定すれば、配列要素をコピーして生成されます。
New の引数として IEnumerator(Of T) が必要なのですが、配列（System.Array）はこれを持っているため、指定ができます。尚、New の引数として List を用いても同様にできます。
AddRange でも同様に引数に配列を指定することができます。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        Dim i As Integer = 0
        ' 配列宣言・初期化
        Dim arr() As Integer = {1, 20, 300}

        ' 配列を指定したListの生成
        Console.WriteLine("=== New(配列) ===")
        Dim list As New List(Of Integer)(arr)
        i = 0
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したListの要素：{1}", i, nVal)
            i += 1
        Next

        ' Listを指定したList2の生成
        Console.WriteLine("=== New(List) ===")
        Dim list2 As New List(Of Integer)(list)
        i = 0
        For Each nVal As Integer In list2
            Console.WriteLine("{0}番目に取得したList2の要素：{1}", i, nVal)
            i += 1
        Next

        ' 配列をListに追加
        Console.WriteLine("=== AddRange ===")
        list.AddRange(arr)
        i = 0
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したListの要素：{1}", i, nVal)
            i += 1
        Next
    End Sub

結果は以下の通りです。

=== New(配列) ===
0番目に取得したListの要素：1
1番目に取得したListの要素：20
2番目に取得したListの要素：300
=== New(List) ===
0番目に取得したList2の要素：1
1番目に取得したList2の要素：20
2番目に取得したList2の要素：300
=== AddRange ===
0番目に取得したListの要素：1
1番目に取得したListの要素：20
2番目に取得したListの要素：300
3番目に取得したListの要素：1
4番目に取得したListの要素：20
5番目に取得したListの要素：300

■簡単な List の宣言と使い方

以下のソースを見て下さい。
処理の前半は、以前の配列を利用した場合の合計処理を示しています。配列の各要素に値を設定する部分は、ベタに記述していますが、合計を求めるところで指標を使ったループ処理で行っています。
処理の後半で List を生成し Add メソッドで新しく要素を追加します。合計を求める処理では配列の様に Item プロパティで要素を取得しています。
尚、 List の要素を指標で取得する場合は、指標は「0」番目から始まります。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        '=== 配列宣言 ===
        Dim arr(5) As Integer
        '要素に値設定
        arr(1) = 1
        arr(2) = 10
        arr(3) = 100
        arr(4) = 1000
        arr(5) = 10000
        '指標宣言
        Dim i As Integer
        '合計計算
        Dim nSum As Integer = 0
        For i = 1 To 5
            nSum = nSum + arr(i)
        Next
        Console.WriteLine("配列を利用した場合の合計処理：{0}", nSum)

        '=== Listの生成 ===
        Dim list As New List(Of Integer)
        '要素に値を追加
        list.Add(1)
        list.Add(10)
        list.Add(100)
        list.Add(1000)
        list.Add(10000)
        nSum = 0
        '合計計算
        For i = 0 To list.Count - 1
            Console.WriteLine("{0}番目のListの要素：{1}", i, list.Item(i))
            nSum = nSum + list.Item(i)
        Next
        Console.WriteLine("List を利用した場合の合計処理：{0}", nSum)
    End Sub

実行結果がコンソールには以下様に表示されます。

配列を利用した場合の合計処理：11111
0番目のListの要素：1
1番目のListの要素：10
2番目のListの要素：100
3番目のListの要素：1000
4番目のListの要素：10000
List を利用した場合の合計処理：11111

■List の繰り返し処理は For Each で行う

上記のソースでは List の要素を Item プロパティで取得しましたが、 For Each 文を使えば List の要素を順次取得できます。（こちらの方が通常よく使います。）
そこで上記のソースを以下の様に変更し実行してみます。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        '=== Listの生成 ===
        Dim list As New List(Of Integer)
        '要素に値を追加
        list.Add(1)
        list.Add(10)
        list.Add(100)
        list.Add(1000)
        list.Add(10000)
        Dim nSum As Integer = 0
        '合計計算
        For Each nVal As Integer In list
            nSum = nSum + nVal
        Next
        Console.WriteLine("List を利用した場合の合計処理：{0}", nSum)
    End Sub

結果は最初の場合と同様になります。

List を利用した場合の合計処理：11111

■List の初期化

List の生成とで一緒に初期化ができます。生成の宣言の後に、From で繋ぎ {}(中括弧) で要素を ,(カンマ) で区切って記述します。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        ' Listの生成（初期化）
        Dim list As New List(Of Integer) From {1, 10, 100, 1000, 10000}
        '指標宣言
        Dim i As Integer = 0
        '合計計算
        Dim nSum As Integer = 0
        '合計計算
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したListの要素：{1}", i, nVal)
            i += 1              '指標＋１
            nSum = nSum + nVal
        Next
        Console.WriteLine("List を利用した場合の合計処理：{0}", nSum)
    End Sub

実行結果は以下の通りで、データの順番は記述した順となっています。

0番目に取得したListの要素：1
1番目に取得したListの要素：10
2番目に取得したListの要素：100
3番目に取得したListの要素：1000
4番目に取得したListの要素：10000
List を利用した場合の合計処理：11111

このソース合計計算の For ループで「5」を直値（リテラル）で記述しています。この場合は「5」であることが明らかなので問題は無いのですが、配列の最終の指標が何か分からない時には UBound 等を用います。以下に項目を新しくして説明します。

■List の定義と各メソッド等について

List クラスは以下の様に定義されています。

Public Class List(Of T)
型パラメーター:
　T：リスト内の要素の型。
概要:
　インデックスを使用してアクセスできる、厳密に型指定されたオブジェクトのリストを表します。
　リストの検索、並べ替え、および操作のためのメソッドを提供します。

「リスト内の要素の型」にはいろんなものが設定可能で、データ型、オブジェクト型、コントロールオブジェクト等が指定できます。また List クラスには以下の様なメソッドがあり、要素に対する各種の処理が可能です。

メソッド or プロパティ	書式	説明
Add	Add(item As T) item：List(Of T) の末尾に追加するオブジェクト	List(Of T) の末尾にオブジェクトを追加します
AddRange	AddRange(collection As IEnumerable(Of T)) collection：List(Of T) の末尾に要素が追加されるコレクション	指定したコレクションの要素を List(Of T) の末尾に追加します
Clear	Clear()	指定List(Of T) からすべての要素を削除します
Count	Count As Integer （これはプロパティ）	List(Of T) に実際に格納されている要素の数を取得します
IndexOf	IndexOf(item As T) As Integer （プロパティ） item：List(Of T) 内で検索するオブジェクト	List(Of T) 全体内で item が見つかった場合は、最初に見つかった位置の 0 から始まるインデックスそれ以外の場合は –1
IndexOf	IndexOf(item As T, index As Integer) As Integer （プロパティ） item：List(Of T) 内で検索するオブジェクト index：検索の開始位置で 0 から始まるインデックス	List(Of T) 全体内で item が見つかった場合は、最初に見つかった位置の 0 から始まるインデックスそれ以外の場合は –1
Insert	Insert(index As Integer, item As T) index：挿入する位置の 0 から始まるインデックス item：挿入するオブジェクト	List(Of T) 内の指定したインデックスの位置に要素を挿入
Item	Item(index As Integer) As T （プロパティ） index：取得,設定する要素の 0 から始まるインデックス例外：ArgumentOutOfRangeException 　index が 0 未満,または List(Of T).Count 以上	指定したインデックスにある要素
Remove	Remove(item As T) As Boolean item：List(Of T) から削除するオブジェクト戻り値： item が正常に削除された場合は true,それ以外は false	List(Of T) 内で最初に見つかった特定のオブジェクトを削除します
RemoveAt	RemoveAt(index As Integer) index：削除する要素の、0 から始まるインデックス例外：ArgumentOutOfRangeException 　index が 0 未満,または List(Of T).Count 以上	List(Of T) の指定したインデックスにある要素を削除します
RemoveRange	RemoveRange(index As Integer, count As Integer) index：削除する要素の範囲の開始位置　　（ 0 から始まるインデックス） count：削除する要素の数例外：ArgumentOutOfRangeException 　 index が 0 未満または count が 0 未満例外：ArgumentException 　 index, count が List(Of T) 内の要素の有効範囲外	List(Of T) から要素の範囲を削除します

上記のメソッド等を順を追って説明します。

AddRange コレクションの要素を末尾に追加
Clear と Count について
IndexOf コレクション要素のインデックスの検索
Insert 指定したインデックスの位置に要素を挿入
Remove RemoveAt RemoveRange 要素の削除

■AddRange コレクションの要素を末尾に追加

2個の List を生成し、最初の List に2番目の List を追加します。この時 (Of T) のデータ型が同じで無い場合はエラーが発生します。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        '指標宣言
        Dim i As Integer = 0

        ' Listの生成（初期化）
        Dim list As New List(Of Integer) From {1, 10, 100, 1000, 10000}
        Dim listAdd As New List(Of Integer) From {2, 20, 200}

        ' AddRange 
        Console.WriteLine("=== AddRange ===")
        list.AddRange(listAdd)
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したListの要素：{1}", i, nVal)
            i += 1              '指標＋１
        Next

        ' 異なる型のList
        Dim listAdd2 As New List(Of Long) From {3, 30, 300}
        Try
            ' エラーが必ず発生
            list.AddRange(listAdd2)
        Catch ex As Exception
            Console.WriteLine("AddRangeエラー：{0}", ex.Message)
        End Try
    End Sub

実行結果は以下の通りです。最初の AddRange で List の末尾に追加されたことが分かります。また、異なるデータ型の場合にはエラーが発生しています。

=== AddRange ===
0番目に取得したListの要素：1
1番目に取得したListの要素：10
2番目に取得したListの要素：100
3番目に取得したListの要素：1000
4番目に取得したListの要素：10000
5番目に取得したListの要素：2
6番目に取得したListの要素：20
7番目に取得したListの要素：200
AddRangeエラー：型 'System.Collections.Generic.List`1[System.Int64]' のオブジェクトを型 'System.Collections.Generic.IEnumerable`1[System.Int32]' にキャストできません。

■Clear と Count について

先ず List を生成しその一覧を Item プロパティで取得し、その後 Clear で List の要素を全て削除します。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        '指標宣言
        Dim i As Integer = 0
        ' Listの生成（初期化）
        Dim list As New List(Of Integer) From {1, 10, 100}
        ' Listの一覧
        Console.WriteLine("=== Listの一覧 ===")
        For i = 0 To list.Count - 1
            Console.WriteLine("{0}番目のListの要素：{1}", i, list.Item(i))
        Next

        Console.WriteLine("=== Clear ===")
        ' Clear
        list.Clear()
        Console.WriteLine("Listの要素個数：{0}", list.Count)
        i = 0
        For Each nVal As Integer In list    ' ForEachでの一覧は処理されない
            Console.WriteLine("{0}番目に取得したListの要素：{1}", i, nVal)
            i += 1              '指標＋１
        Next
    End Sub

実行結果は以下の通りです。Count で List の件数分の一覧処理が行われることが分かります。また Clear 後は件数が「0」になり For Each での処理が行われません。

=== Listの一覧 ===
0番目のListの要素：1
1番目のListの要素：10
2番目のListの要素：100
=== Clear ===
Listの要素個数：0

■IndexOf コレクション要素のインデックスの検索

先ず List を生成しその要素の値指定でインデックスを IndexOf 関数で取得します。
その後、検索開始インデックスを指定する IndexOf での例を以下に示します。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        Dim i As Integer = 0

        ' Listの生成（初期化）                   0   1    2     3      4  5   6    7
        Dim list As New List(Of Integer) From {1, 10, 100, 1000, 10000, 2, 20, 200}

        ' IndexOf(item As T)
        Console.WriteLine("=== IndexOf(item As T) ===")
        i = list.IndexOf(1000)
        Console.WriteLine("itemが「{0}」のインデックス：{1}", 1000, i)
        i = list.IndexOf(1500)
        Console.WriteLine("itemが「{0}」のインデックス：{1}", 1500, i)

        ' IndexOf(item As T, index As Integer)
        Console.WriteLine("=== IndexOf(item As T, index As Integer) ===")
        i = list.IndexOf(20, 4)
        Console.WriteLine("itemが「{0}」をインデックス「{1}」から検索した結果のインデックス：{2}", 20, 4, i)
        i = list.IndexOf(1000, 4)
        Console.WriteLine("itemが「{0}」をインデックス「{1}」から検索した結果のインデックス：{2}", 1000, 4, i)
    End Sub

実行結果は以下の通りです。
要素の値指定のみの IndexOf では先頭から検索する為「1000」の値の場合はインデックス「3」が返り、「1500」の値の場合は List の要素に存在しないので「-1」が返ります。
検索開始インデックスを指定する IndexOf では開始インデックスを「4」とし、検索要素値「20」の場合は「6」が返り、検索要素値「1000」の場合はインデックスを「4」以降には値が存在しないので「-1」が返ります。

=== IndexOf(item As T) ===
itemが「1000」のインデックス：3
itemが「1500」のインデックス：-1
=== IndexOf(item As T, index As Integer) ===
itemが「20」をインデックス「4」から検索した結果のインデックス：6
itemが「1000」をインデックス「4」から検索した結果のインデックス：-1

■Insert 指定したインデックスの位置に要素を挿入

先ず List を生成しインデックス「5」の位置に「300」を挿入します。
その後、存在しないインデックス「10」の位置に挿入処理を行いエラーが発生することを確認します。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        Dim i As Integer = 0

        ' Listの生成（初期化）
        Dim list As New List(Of Integer) From {1, 10, 100, 1000, 10000, 2, 20, 200}

        ' Insert(index As Integer, item As T)
        Console.WriteLine("=== Insert(index As Integer, item As T) ===")
        list.Insert(5, 300) 'インデックス「5」の位置に「300」を挿入
        i = 0
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したListの要素：{1}", i, nVal)
            i += 1              '指標＋１
        Next
        Try
            ' エラーが必ず発生
            list.Insert(10, 900) 'インデックス「10」の位置に「900」を挿入
        Catch ex As Exception
            Console.WriteLine("Insertエラー：{0}", ex.Message)
        End Try
    End Sub

=== Insert(index As Integer, item As T) ===
0番目に取得したListの要素：1
1番目に取得したListの要素：10
2番目に取得したListの要素：100
3番目に取得したListの要素：1000
4番目に取得したListの要素：10000
5番目に取得したListの要素：300
6番目に取得したListの要素：2
7番目に取得したListの要素：20
8番目に取得したListの要素：200
Insertエラー：インデックスは一覧の範囲内になければなりません。
パラメーター名:index

■Remove RemoveAt RemoveRange 要素の削除

先ず List を生成し Remove で値が「300」の要素を削除します。2回行うことで異なる結果が返ってくるはずです。
その後 RemoveAt でインデックス「5」の位置を削除処理を行い一覧確認します。さらに存在しないインデックス「10」の位置を削除処理し、エラー発生を確認します。
その後 RemoveRange でインデックス「3」の位置から「2」個の要素を削除処理を行い一覧確認します。さらにインデックス「3」の位置から存在しない個数の「5」で削除処理し、エラー発生を確認します。

    Private Sub btnList_Click(sender As Object, e As EventArgs) Handles btnList.Click
        Dim i As Integer = 0

        ' Listの生成（初期化）
        Dim list As New List(Of Integer) From {1, 10, 100, 1000, 10000, 300, 2, 20, 200}

        Dim blnRet As Boolean
        ' Remove(item As T)
        Console.WriteLine("=== Remove(item As T) ===")
        blnRet = list.Remove(300)
        Console.WriteLine("itemが「{0}」削除：{1}", 300, blnRet)
        blnRet = list.Remove(300)
        Console.WriteLine("itemが「{0}」削除：{1}", 300, blnRet)

        ' RemoveAt(index As Integer)
        Console.WriteLine("=== RemoveAt(index As Integer) ===")
        list.RemoveAt(5)
        Console.WriteLine("インデックス「{0}」の要素を削除", 5)
        i = 0
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したListの要素：{1}", i, nVal)
            i += 1              '指標＋１
        Next
        Try
            ' エラーが必ず発生
            list.RemoveAt(10) 'インデックス「10」の位置の要素削除
        Catch ex As Exception
            Console.WriteLine("RemoveAtエラー：{0}", ex.Message)
        End Try

        ' RemoveRange(index As Integer, count As Integer)
        Console.WriteLine("=== RemoveRange(index As Integer, count As Integer) ===")
        list.RemoveRange(3, 2)
        Console.WriteLine("インデックス「{0}」から「{1}」個の要素を削除", 3, 2)
        i = 0
        For Each nVal As Integer In list
            Console.WriteLine("{0}番目に取得したListの要素：{1}", i, nVal)
            i += 1              '指標＋１
        Next
        Try
            ' エラーが必ず発生
            list.RemoveRange(3, 5)
        Catch ex As Exception
            Console.WriteLine("RemoveRangeエラー：{0}", ex.Message)
        End Try
    End Sub

実行結果は以下の通りです。

=== Remove(item As T) ===
itemが「300」削除：True
itemが「300」削除：False
=== RemoveAt(index As Integer) ===
インデックス「5」の要素を削除
0番目に取得したListの要素：1
1番目に取得したListの要素：10
2番目に取得したListの要素：100
3番目に取得したListの要素：1000
4番目に取得したListの要素：10000
5番目に取得したListの要素：20
6番目に取得したListの要素：200
RemoveAtエラー：インデックスが範囲を超えています。負でない値で、コレクションのサイズよりも小さくなければなりません。
パラメーター名:index
=== RemoveRange(index As Integer, count As Integer) ===
インデックス「5」から「2」個の要素を削除
0番目に取得したListの要素：1
1番目に取得したListの要素：10
2番目に取得したListの要素：100
3番目に取得したListの要素：20
4番目に取得したListの要素：200
RemoveRangeエラー：配列のオフセットおよび長さが範囲を超えているか、カウンターがソース コレクションのインデックスから最後までの要素の数より大きい値です。

オブジェクト型からString型への変換

    ''' 
    ''' Object型からString型にデータ変換
    ''' 
    ''' <param>元のObject</param>
    ''' String型に変換後の値
    ''' String型に変換できない場合は「""」を返す
    Function ObjToStr(ByVal objSrc As Object) As String
        Dim strRet As String
        Try
            If objSrc Is Nothing Then
                'Objectデータが「Nothing」の場合
                strRet = ""
            ElseIf IsDBNull(objSrc) Then
                'Objectデータが「DBNULL」の場合
                strRet = ""
            Else
                '文字列に変換
                strRet = CStr(objSrc)
            End If

        Catch ex As Exception
            'エラーの場合
            strRet = ""
        End Try
        '変換値を返す
        Return strRet
    End Function

このオブジェクト型から文字列型への変換関数を利用して、オブジェクト型からInteger型への変換関数を宣言します。

オブジェクト型からInteger型への変換

    ''' 
    ''' Object型からInteger型にデータ変換
    ''' 
    ''' <param>元のObject</param>
    ''' Integer型に変換後の値
    ''' Integer型に変換できない場合は「0」を返す
    Function ObjToInt(ByVal objSrc As Object) As Integer
        Dim intRet As Integer
        Try
            'String型に変換
            Dim strSrc As String = ObjToStr(objSrc)
            'Integer型に変換
            If Integer.TryParse(strSrc, intRet) = False Then
                '変換が不可の場合
                intRet = 0
            End If

        Catch ex As Exception
            'エラーの場合
            intRet = 0
        End Try
        '変換値を返す
        Return intRet
    End Function

更にオブジェクト型からDecimal型への変換は以下の様になります。（その他のDouble型とかも同様に宣言できます）

オブジェクト型からDecimal型への変換

    ''' 
    ''' Object型からDecimal型にデータ変換
    ''' 
    ''' <param>元のObject</param>
    ''' Decimal型に変換後の値
    ''' Decimal型に変換できない場合は「0」を返す
    Function ObjToDec(ByVal objSrc As Object) As Decimal
        Dim decRet As Decimal
        Try
            'String型に変換
            Dim strSrc As String = ObjToStr(objSrc)
            'Decimal型に変換
            If Decimal.TryParse(strSrc, decRet) = False Then
                '変換が不可の場合
                decRet = 0
            End If

        Catch ex As Exception
            'エラーの場合
            decRet = 0
        End Try
        '変換値を返す
        Return decRet
    End Function

■各データ型について

データ型	型説明	サイズ	有効桁数	値の範囲
Integer	整数型	4バイト		-2147483648 ～ 2147483647
Long	長整数型	8バイト		-9223372036854775808 ～ 9223372036854775807
Single	単精度浮動小数点型	4バイト	7桁	-3.40282347E+38 ～ 3.40282347E+38
Double	倍精度浮動小数点型	8バイト	15桁	-1.7976931348623157E+308 ～ 1.7976931348623157E+308
Decimal	10進型	16バイト	28桁	-7.9228162514264337594E+28 ～ 7.9228162514264337594E+28

Single 型と Double 型について
Decimal 型について
リテラル（直値）宣言の注意

■Single 型と Double 型について

浮動小数点型は内部的に符号部、指数部、仮数部に分けてデータを持っているそうです。 Single 型は符号部(1ビット)、指数部(8ビット)、仮数部(23ビット) で Double 型は符号部(1ビット)、指数部(11ビット)、仮数部(52ビット) で構成されているらしいです。（詳しくは IEEE 754 の説明にあたって下さい。）

Single 型 Double 型の計算を行わせてどのくらいの精度があるのかを見てみます。
以下のソースでは小数「0.1」を10回加算して結果を有効桁20桁までで表示させています。「0.1」と言う数値は2進数にすると「0.00011001100110011…」の循環小数になることはよく知られています。これを10回加算して結果が数学的に「1」になるでしょうか？

    Private Sub btnTest_Click(sender As Object, e As EventArgs) Handles btnTest.Click
        '単精度数値変数
        Dim sngVal As Single = 0
        '倍精度数値変数
        Dim dblVal As Double = 0
        'それぞれ「0.1」を10回加算
        For i As Integer = 1 To 10
            sngVal += 0.1F  'リテラルで「F」指定は単精度数値
            dblVal += 0.1D  'リテラルで「D」指定は倍精度数値
        Next
        '結果が「1」になることを期待?
        Console.WriteLine("Single Data = {0}", sngVal.ToString("G20"))
        Console.WriteLine("Double Data = {0}", dblVal.ToString("G20"))
    End Sub

実行結果がコンソールには以下様に表示されます。やはり「1」にはなりません。リテラルで加算される「0.1」は循環小数なので内部的にはどこかで丸めが発生しているからです。

Single Data = 1.00000012
Double Data = 0.99999999999999989

Single 型では有効桁数が少ないので、小数以下4桁どうしの乗算を行うと小数以下8桁まで必要になりますが、小数以下8桁以降は信頼できない値になります。これでは科学計算には向かないので、 Double 型を使うことになります。

■Decimal 型について

上記の処理を Decimal 型に変えて処理します。

    Private Sub btnTest_Click(sender As Object, e As EventArgs) Handles btnTest.Click
        '10新型数値変数
        Dim decVal As Decimal = 0
        '「0.1」を10回加算
        For i As Integer = 1 To 10
            decVal += 0.1D  'リテラルで「D」指定は10新型数値
        Next
        '結果が「1」になることを期待?
        Console.WriteLine("Decimal Data = {0}", decVal.ToString("G20"))
        decVal = 0.1D
        Console.WriteLine("Decimal Data = {0}", decVal.ToString("G30"))
    End Sub

実行結果がコンソールには以下様に表示されます。確かにこの程度の小数以下の精度では問題無い様です。

Decimal Data = 1
Decimal Data = 0.1

Decimal 型はデータサイズも大きく内部での計算は他の型よりも時間が掛かりますが、会計処理などでは小数点以下の精度に正確性が求められますので、この型を使います。
私が組むプログラムは OA 系の処理が多いので数値は全て Decimal 型を使っています。まれに、工場のライン監視などで計測データが必要なときは Double 型も使いますが、そこまで速度が要求されなければ Decimal 型を使います。

■リテラル（直値）宣言の注意

プログラム上で直接値（リテラル）を宣言する場合に注意が必要です。値を正しく宣言しないと期せずして異なるデータ型で処理されてることがあります。
以下のソースは小数点付きで宣言した場合と、小数点無し（整数）で宣言した場合に、数値の後ろにデータ型を指示する文字を付加する場合としない場合の例を示します。

    Private Sub btnTest_Click(sender As Object, e As EventArgs) Handles btnTest.Click
        '各種データ型を入れるため「Object」型
        Dim objTest As Object = Nothing

        'Decimal型のリテラル
        objTest = 0.1
        Console.WriteLine("Type = {0}", objTest.GetType.ToString)

        'Single型のリテラル
        objTest = 0.1F
        Console.WriteLine("Type = {0}", objTest.GetType.ToString)

        'Integer型のリテラル
        objTest = 12345
        Console.WriteLine("Type = {0}", objTest.GetType.ToString)

        'Long型のリテラル
        objTest = 12345L
        Console.WriteLine("Type = {0}", objTest.GetType.ToString)
    End Sub

実行結果がコンソールには以下様に表示されます。

Type = System.Double
Type = System.Single
Type = System.Int32
Type = System.Int64

■各データ型のリテラル指定について

データ型	型説明	リテラル指定
Integer	整数型	I
Long	長整数型	L
Single	単精度浮動小数点型	F
Double	倍精度浮動小数点型	R
Decimal	10進型	D

VB.NET-TIPS などプログラミングについて

■簡単な Dictionary の宣言と使い方

■Dictionary の繰り返し処理は For Each で行う

■Dictionary の初期化

■Dictionary の各メソッド・プロパティ等について

■Clear と ContainsKey と Count について

■IndexOf コレクション要素のインデックスの検索

■Insert 指定したインデックスの位置に要素を挿入

■Remove RemoveAt RemoveRange 要素の削除

関連する記事

■List から配列への変換（ToArray, CopyTo）

■List の生成(New)で配列指定

関連する記事

■簡単な List の宣言と使い方

■List の繰り返し処理は For Each で行う

■List の初期化

■List の定義と各メソッド等について

■AddRange コレクションの要素を末尾に追加

■Clear と Count について

■IndexOf コレクション要素のインデックスの検索

■Insert 指定したインデックスの位置に要素を挿入

■Remove RemoveAt RemoveRange 要素の削除

関連する記事

オブジェクト型からString型への変換

オブジェクト型からInteger型への変換

オブジェクト型からDecimal型への変換

関連する記事

■各データ型について

■Single 型と Double 型について

■Decimal 型について

■リテラル（直値）宣言の注意

■各データ型のリテラル指定について

関連する記事