ComboBoxの簡単な拡張クラス｜VB.NET-TIPS などプログラミングについて

2018/03/22

VB.NETの ComboBox には枠線(ボーダー)を表示するプロパティが標準ではありません。
ComboBox の FlatStyle を Flat に設定すると、枠線が白色になりよく見えなくなります。そこで、 ComboBox の簡単な拡張クラスをとして枠線の色を追加のプロパティとして作成しました。
クラス名は名前は ComboBoxEx とします。

ウインドウメッセージの処理の中で、 WM_PAINT のメッセージの処理でコンボボックスコントロールの枠を描画します。枠線を指定する為のプロパティを BorderColor として定義しています。

ComboBoxの簡単な拡張クラス

Imports System
Imports System.ComponentModel
Imports System.Drawing
Imports System.Drawing.Drawing2D
Imports System.Windows.Forms
 
''' <summary>
''' 拡張コンボボックスコントロール
''' </summary>
''' <remarks></remarks>
Public Class ComboBoxEx
    Inherits System.Windows.Forms.ComboBox
 
    Private Const WM_PAINT As Integer = &HF
 
    ''' <summary>
    ''' コンストラクタ
    ''' </summary>
    Sub New()
        'ComboBoxのコンストラクタを呼ぶ
        MyBase.New()
    End Sub
 
    ''' <summary>
    ''' Windowsメッセージ処理
    ''' </summary>
    '''
    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        Select Case m.Msg
            Case WM_PAINT
                'ペイントイベントでデフォルトの処理をさせる
                MyBase.WndProc(m)
                'その後で強制的に枠描画
                Call DrawRectangle()
 
            Case Else
                MyBase.WndProc(m)
        End Select
    End Sub
 
    ''' <summary>
    ''' 枠描画関数
    ''' </summary>
    ''' <remarks>再定義可能関数</remarks>
    Protected Overridable Sub DrawRectangle()
        'グラフィッククラスの参照取得
        Dim g As Graphics = Me.CreateGraphics()
        '枠の四角い領域
        Dim rect As Rectangle = Me.ClientRectangle
        '描画用のペン生成
        Dim framePen As New Pen(Me.BorderColor)
        Try
            '枠描画
            g.DrawRectangle(framePen, rect.X, rect.Y, rect.Width - 1, rect.Height - 1)
        Catch ex As Exception
        Finally
            'ペンの解放
            framePen.Dispose()
        End Try
    End Sub
 
    'ボーダー色退避
    Private _BorderColor As Color = System.Drawing.SystemColors.ControlText
 
    ''' <summary>
    ''' ボーダー色プロパティ
    ''' </summary>
    ''' <value>Color値</value>
    ''' <returns>Color値</returns>
    Public Property BorderColor() As Color
        Get
            Return Me._BorderColor
        End Get
        Set(ByVal value As Color)
            Me._BorderColor = value
        End Set
    End Property
 
End Class