VB.NET-TIPS などプログラミングについて

2019/02/06

今回は日付型データの比較を取り扱います。日付型データはその変数名を使って直接 If 文等で比較することが出来ます。数値データの様に日付型データを比較演算子で結んで値の大小等が比較できます。

以下の例は2個の日付型データに 2019/02/01 と 2019/02/02 の異なる日付を設定し、等しいかどうかの判定を If 文で行っています。

簡単な日付型（Date）データの比較

    Dim dateWK1 As Date = New DateTime(2019, 2, 1)  '2019/02/01
    Dim dateWK2 As Date = New DateTime(2019, 2, 2)  '2019/02/02
    '2個の日時の比較
    If dateWK1 = dateWK2 Then
        Console.WriteLine("dateWK1 と dateWK2 は等しい")
    Else
        Console.WriteLine("dateWK1 と dateWK2 は異なる")
    End If
    Console.WriteLine("dateWK1：" & dateWK1.ToString("yyyy/MM/dd HH:mm:ss"))
    Console.WriteLine("dateWK2：" & dateWK2.ToString("yyyy/MM/dd HH:mm:ss"))

実行結果は当然、2個の日付型データが異なっていることが分かります。

dateWK1 と dateWK2 は異なる
dateWK1：2019/02/01 00:00:00
dateWK2：2019/02/02 00:00:00

上の例では問題無く判定が行われましたが、以下の例を見て下さい。上の例の様に、2個の日付型データは変数を Date として宣言し、最初の変数に Now() 関数で現在日時を設定し、さらにその後10秒待った後で、2個目の変数に現在日時を設定しています。その後、2個の変数を比較すると、やはり異なっているとの判定がされます。

2個の変数の中身を表示してやれば、最初の時刻から10秒経過した時刻が設定されていることが分かります。
これは当然と言えばそうなのですが、変数が Date 型だからと勘違いして、日付部分しか比較しないのかと考えるとミスが発生します。お恥ずかしい話、私自身も以前にはこれでバグを発生させたことがありました。

日付型（Date）データの比較

    '現在日時を取得
    Dim dateWK1 As Date = Now()
    '10秒待つ
    System.Threading.Thread.Sleep(10 * 1000)
    '現在日時を取得
    Dim dateWK2 As Date = Now()    '2個の日時の比較
    If dateWK1 = dateWK2 Then
        Console.WriteLine("dateWK1 と dateWK2 は等しい")
    Else
        Console.WriteLine("dateWK1 と dateWK2 は異なる")
    End If
    Console.WriteLine("dateWK1：" & dateWK1.ToString("yyyy/MM/dd HH:mm:ss"))
    Console.WriteLine("dateWK2：" & dateWK2.ToString("yyyy/MM/dd HH:mm:ss"))
    '日付型データの比較関数
    Console.WriteLine("Date.Compare(dateWK1, dateWK2)：" & Date.Compare(dateWK1, dateWK2))

上記の処理を実行すると以下の様な表示が、「出力」ウインドウに表示されます。

dateWK1 と dateWK2 は異なる
dateWK1：2019/02/06 18:16:49
dateWK2：2019/02/06 18:16:59
Date.Compare(dateWK1, dateWK2)：-1

Date 型にはプロパティとして Date というものを持っているのでこれを使うと純然たる日付のみのデータが取得できますので、日付のみの比較が正しく行えます。以下のソースは If 文の部分を変更して実行してみました。

日付型（Date）データの日付のみの比較

    '現在日時を取得
    Dim dateWK1 As Date = Now()
    '10秒待つ
    System.Threading.Thread.Sleep(10 * 1000)
    '現在日時を取得
    Dim dateWK2 As Date = Now()
    '2個の日時の比較
    If dateWK1.Date = dateWK2.Date Then
        Console.WriteLine("dateWK1 と dateWK2 は等しい")
    Else
        Console.WriteLine("dateWK1 と dateWK2 は異なる")
    End If

上記の処理を実行すると以下の様な表示が、「出力」ウインドウに表示されます。

dateWK1 と dateWK2 は等しい

さらに日付型の Compare メソッドを使って比較処理ができます。

Date.Compare( para1, para2 ) ... 「-1, 0, 1」のInteger型の値を返します。
結果の値の意味は以下の通りです。
・[-1] : para1 ＜ para2 
・[ 0] : para1 ＝ para2 
・[ 1] : para1 ＞ para2

日付型の Compare メソッドでの比較

    Dim date0 As New DateTime(2019, 8, 27, 10, 30, 0)
    Dim date1 As New DateTime(2019, 8, 26, 10, 10, 0)
    Dim date2 As New DateTime(2019, 8, 27, 10, 15, 0)
    Dim date3 As New DateTime(2019, 8, 28, 10, 20, 0)

    ' 日付のみで比較
    Console.WriteLine("Compare(date1.Date, date0.Date) = {0}", Date.Compare(date1.Date, date0.Date))
    Console.WriteLine("Compare(date2.Date, date0.Date) = {0}", Date.Compare(date2.Date, date0.Date))
    Console.WriteLine("Compare(date3.Date, date0.Date) = {0}", Date.Compare(date3.Date, date0.Date))

    ' 日付の時刻を含み比較
    Console.WriteLine("Compare(date1, date0) = {0}", Date.Compare(date1, date0))
    Console.WriteLine("Compare(date2, date0) = {0}", Date.Compare(date2, date0))
    Console.WriteLine("Compare(date3, date0) = {0}", Date.Compare(date3, date0))

上記の処理を実行すると以下の様な表示が、「出力」ウインドウに表示されます。

Compare(date1.Date, date0.Date) = -1
Compare(date2.Date, date0.Date) = 0
Compare(date3.Date, date0.Date) = 1
Compare(date1, date0) = -1
Compare(date2, date0) = -1
Compare(date3, date0) = 1

DateTime型の CompareTo メソッドを使っても同様の結果が得られます。

DateTime型の CompareTo メソッドでの比較

    Dim date0 As New DateTime(2019, 8, 27, 10, 30, 0)
    Dim date1 As New DateTime(2019, 8, 26, 10, 10, 0)
    Dim date2 As New DateTime(2019, 8, 27, 10, 15, 0)
    Dim date3 As New DateTime(2019, 8, 28, 10, 20, 0)

    ' さらにDateTime型のCompareToを利用
    Console.WriteLine("date1.Date.CompareTo(date0.Date) = {0}", date1.Date.CompareTo(date0.Date))
    Console.WriteLine("date2.Date.CompareTo(date0.Date) = {0}", date2.Date.CompareTo(date0.Date))
    Console.WriteLine("date3.Date.CompareTo(date0.Date) = {0}", date3.Date.CompareTo(date0.Date))

テキストボックスの電卓の様な入力コントロールクラス

Public Class ClsNumTextBox3
    Inherits TextBox

    '数値桁数("-",","を含まない数値の桁数)
    Private _NumericUnits As Integer = 9
    '数値マイナスフラグ
    Private _fMinus As Boolean = False

    'クリップボード貼付メッセージ
    Const WM_PASTE As Integer = &H302

    ''' 
    ''' コンストラクタ
    ''' 
    Public Sub New()
        MyBase.New()
        'IMEを無効にする
        MyBase.ImeMode = ImeMode.Disable
        'MaxLengthは取り敢えず16を設定
        Me.MaxLength = 16
        'テキストは右寄せ
        Me.TextAlign = HorizontalAlignment.Right
    End Sub

    ''' 
    ''' WndProc メソッド(クリップボード処理の為)
    ''' 
    ''' <param name="m">メッセージ</param>
    Protected Overrides Sub WndProc(ByRef m As Message)
        Select Case m.Msg
            Case WM_PASTE
                'クリップボードからのコピーは処理しない
                Return
        End Select

        'メッセージのデフォルト処理を呼出す
        MyBase.WndProc(m)
    End Sub

    ''' 
    ''' 数値桁数プロパティ
    ''' 
    Public WriteOnly Property NumericUnits As Integer
        Set(value As Integer)
            Me._NumericUnits = value   '退避値に設定
        End Set
    End Property

    ''' 
    ''' 数値での取得設定プロパティ
    ''' 
    ''' 設定値
    ''' 取得値
    Public Property Value As Decimal
        Set(value As Decimal)
            Dim strNum As String = Math.Abs(value).ToString
            If strNum.Length > Me._NumericUnits Then
                MsgBox("ERR:数値桁数 " & Me._NumericUnits & " より大きい値が設定された")
            Else
                Me._fMinus = (value < 0)    'マイナスフラグ設定
                Me.Text = strNum            '取敢えず数値文字列設定
                Call Me.RepairNumString("", Me._fMinus)
            End If
        End Set
        Get
            '文字列からカンマ除去
            Dim strNum As String = Me.Text.Replace(",", "")
            'Decimal変換値を返す
            Return ToDec(strNum)
        End Get
    End Property

    ''' 
    ''' KeyDownイベントの処理
    ''' 
    Protected Overrides Sub OnKeyDown(e As KeyEventArgs)
        MyBase.OnKeyDown(e)

        Dim strAdd As String = ""
        Dim fEdit As Boolean = False

        'キーコードによる処理
        Select Case e.KeyCode
            Case Keys.Enter
                If e.Control = False Then
                    '[Ctrl]キーが押下されていない場合、自分の親のコントロールの次のフォーカスへ移動
                    Me.Parent.SelectNextControl(Me, Not e.Shift, True, True, True)
                End If

            Case Keys.Up, Keys.Down, Keys.Left, Keys.Right
                e.Handled = True

            Case Keys.D0 To Keys.D9, Keys.NumPad0 To Keys.NumPad9
                'キーが [0]～[9]
                '入力文字列が数値桁数を超えないかチェック
                Dim strNum As String = Me.Text.Replace("-", "").Replace(",", "")
                If strNum.Length >= Me._NumericUnits Then
                    e.Handled = True
                Else
                    Select Case e.KeyCode
                        Case Keys.D0 To Keys.D9
                            strAdd = "0123456789".Substring(e.KeyCode - Keys.D0, 1)
                        Case Keys.NumPad0 To Keys.NumPad9
                            strAdd = "0123456789".Substring(e.KeyCode - Keys.NumPad0, 1)
                    End Select
                    fEdit = True            '編集表示フラグON
                    e.Handled = True
                End If

            Case Keys.Subtract
                'キーが [-]
                Me._fMinus = Not Me._fMinus 'マイナスフラグ反転
                fEdit = True                '編集表示フラグON

            Case Keys.Back
                '最後尾1文字削除
                RepairNumString("", Me._fMinus, True)
                Me.SelectionStart = Me.Text.Length
                If Me.Text.Length = 0 Then
                    '文字列が空になった場合はマイナスフラグOFF
                    Me._fMinus = False
                End If
                e.Handled = True

            Case Else
                e.Handled = True

        End Select

        If fEdit = True Then
            '編集表示フラグONの場合、編集表示
            Call Me.RepairNumString(strAdd, Me._fMinus)
            Me.SelectionStart = Me.Text.Length
        End If
    End Sub

    ''' 
    ''' KeyPressイベントの処理
    ''' 
    Protected Overrides Sub OnKeyPress(e As KeyPressEventArgs)
        MyBase.OnKeyPress(e)

        '全ての文字をイベントをキャンセル
        e.Handled = True
    End Sub

    ''' 
    ''' MouseDownイベント処理
    ''' 
    Protected Overrides Sub OnMouseDown(e As MouseEventArgs)
        MyBase.OnMouseDown(e)
        If Not (Me.SelectionStart = Me.Text.Length) Then
            'カーソル位置を最後尾に強制移動
            Me.SelectionStart = Me.Text.Length
        End If
    End Sub

    ''' 
    ''' 文字列の編集表示
    ''' 
    ''' <param name="strAdd">最後尾付加文字</param>
    ''' <param name="fMinus">数値マイナスフラグ</param>
    ''' <param name="fBackSpace">BACKSPACEフラグ</param>
    ''' 文字列を3桁ごとにカンマ編集する
    Private Sub RepairNumString(ByVal strAdd As String,
                                ByVal fMinus As Boolean,
                                Optional fBackSpace As Boolean = False)
        '文字を最後に追加する
        Dim strNum As String = Me.Text.Replace("-", "").Replace(",", "") & strAdd
        If fBackSpace = True Then
            'BackSpaceの指定の場合、最後の文字を削除
            If strNum <> "" Then
                strNum = strNum.Substring(0, strNum.Length - 1)
            End If
        End If
        '3桁ごとのカンマ表示
        Dim str As String = Me.ToDec(strNum).ToString("#,###")
        'マイナスの場合は"-"付加
        If fMinus = True Then
            If str <> "" Then
                str = "-" & str
            End If
        End If
        Me.Text = str
        'マイナスの場合は赤色設定
        If fMinus = True Then
            If Not Me.ForeColor = Color.Red Then
                Me.ForeColor = Color.Red
            End If
        Else
            If Not Me.ForeColor = Color.Black Then
                Me.ForeColor = Color.Black
            End If
        End If
    End Sub

    ''' 
    ''' 文字列をDecimal数値変換
    ''' 
    ''' <param name="str">文字列</param>
    ''' 変換後の数値
    Private Function ToDec(ByVal str As String) As Decimal
        Dim dec As Decimal = 0
        Try
            If str <> "" Then
                dec = CDec(str)
            End If
        Catch ex As Exception
        End Try
        Return dec
    End Function

End Class

今回のコントロールを２個とボタンをフォームに張り付け、そのボタンで１個目の数値を２個目の数値コントロールにコピーを行う例を以下に示します。

電卓風数値入力コントロールの例

Public Class frmTextBox3

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Try
            Dim dec As Decimal = Me.NumTextBox1.Value
            Me.NumTextBox2.Value = dec
        Catch ex As Exception
        End Try
    End Sub

End Class