VB.NET-TIPS などプログラミングについて

Main
	SCREEN 1				'漢字モード
	LOCATE , , 2			'カーソルをブロック表示

	ON ERROR GOTO MAIN.ERR
	'FIELDのカラム数の定義
	Const COL.CD% = 4
	Const COL.NUM% = 8
	'TEST.DATファイルを、ファイル番号#1としてオープンします
	PRIVATE FILENO%, strCD$, lngNum&, REC.CD$, REC.NUM$
	FILENO% = 1
	OPEN "TEST.DAT" AS FILENO% RECORD 2147483647
	FIELD #FILENO%, COL.CD% AS REC.CD$, COL.NUM% AS REC.NUM$
	strCD$ = "1"
	lngNum& = 1000
	REC.CD$  = LEFT$(strCD$ + "    ", COL.CD%)	'既定の桁数分スペースを付加
	REC.NUM$ = RIGHT$("        " + STR$(lngNum&), COL.NUM%)	'既定の桁数分スペースを付加
	'書込み
	PUT #FILENO%
	'クローズ
	CLOSE #FILENO%
	
	'FIELDのカラム数の追加定義
	Const COL.DTX% = 4
	PRIVATE strDTX$
	OPEN "TEST.DAT" AS FILENO% RECORD 2147483647
	'カラム数を追加してFIELD文
	FIELD #FILENO%, COL.CD% AS REC.CD$, COL.NUM% AS REC.NUM$, COL.DTX% AS strDTX$
	'書込み
	PUT #FILENO%
	'クローズ
	CLOSE #FILENO%
	'
	WAIT 0, &H1
	END
MAIN.ERR
	PRINT "ERL=";ERL;" ERR=";HEX$(ERR);
	WAIT 0, &H1
	END

[書式]
　OPEN "COM4:M, サービスプロファイル [, [デバイスアドレス][, [パスキー][, [タイムアウト]
[, [セキュリティモード]]]]]" AS [#] ファイル番号
＜引き数＞
・[COM4:M]は自分自身をマスタとして接続先をスレーブとする
・サービスプロファイル
　■SDAP：サービス検索
　■SPP：シリアルポートプロファイル
　■DUN：ダイヤルアップ接続プロファイル

・［デバイスアドレス］：Bluetooth デバイスアドレス
　　12 文字の16 進数文字列で指定

・［パスキー］：Bluetooth パスキー

・［タイムアウト］：接続が完了までの最大待ち時間(1～255秒)

・［セキュリティモード］：接続時のセキュリティモード
　　1：セキュリティなし
　　2：セキュリティあり
　　3：セキュリティあり、暗号化あり
　　4：シンプルペアリング

OPEN "COM4:M,SPP,112233AABBCC,,30,1" AS #2

  'Bluetoothオープン
  OPEN "COM4:M,SPP,112233AABBCC,,30,1" AS #2
  'シリアル通信処理
  
  '--データ送信処理--
  PRINT #2,"TESTDATA";	'送信データは仮のもの
  
  '--データ受信処理--
  'ここにINPUT$関数などでデータを取得し、
  '各機器ごとに合わせた処理を記述する

  'Bluetoothクローズ
  CLOSE #2

	SCREEN 1				'漢字モード
	LOCATE , , 2			'カーソルをブロック表示

	PRIVATE I%
	PRIVATE strBtAddr$(7)[12]	'Bluetoothデバイスアドレス
	PRIVATE intBtNum%			'Bluetoothデバイス数
	'Bluetooth検出オープン
	OPEN "COM4:I,60,1" AS #2 ' デバイス検出時間:60秒
	'検出機器数:8台
	intBtNum% = 8
	'検出結果を読み出し
	CALL "BT.FN3" .fcBTInqRes intBtNum%, strBtAddr$()
	'Bluetooth検出クローズ
	CLOSE #2
	'検出したBluetoothアドレス表示
	PRINT "BlueTooth-Addr"
	FOR I% = 0 TO 7
		PRINT "Addr" + STR$(I%) + ":" + strBtAddr$(i%)
	NEXT I%
	WAIT 0, &H1
	END

・Bhtprtdm.dll  -- BHT-BASIC4.0 転送ユーティリティライブラリ
・Bhtprt.ini    -- BHT-BASIC4.0 転送ユーティリティライブラリ設定
・Ymodem_pd.dll -- YMODEMプロトコルライブラリ
・BHTIr_pd.dll  -- BHT-Irプロトコルライブラリ

Declare Function ExecProtocol Lib "Bhtprtdm.dll" (_
	ByVal hWnd As IntPtr, _
        ByVal Param As String, _
        ByVal FileName As System.Text.StringBuilder, _
        ByVal Protocol As Integer) As Integer
[引数]
 hWnd	 :DLLを呼び出すウィンドウハンドルを設定
 Param	 :ファイル転送の動作を制御するオプションの文字列
          (1つのファイル名と複数のオプションをスペースで区切った文字列)
 FileName:転送したパス名/ファイル名を格納
 Protocol:プロトコル番号を指定

[戻り値]
 Integer型の値で、0(Er_NOERROR)はエラー無しで、
 0以外は伝送エラー在り
 (エラー内容はDENSO提供のBASICソースを参照)

【伝送速度】
 +B

"+B9600"     9600 bps
"+B19200"   19200 bps
"+B38400"   38400 bps
"+B57600"   57600 bps
"+B115200" 115200 bps
"+B230400" 230400 bps
"+B460800" 460800 bps

YMODEM時
"+B115200"

BHT-Ir時
"+B9600"
 

【通信ポート】
 +Pn

+Pn (n = 1 ～ 99)

【ファイルフィールド】
 +Fn
 +F
 -F

[+Fn]の場合:"+Fa,b,c..."
 a:フィールド1桁数
 b:フィールド2桁数
 c:フィールド3桁数
 ...
[+F]の場合:既存フィールドファイルによる
  (YMODEMのみ)
　※受信の場合はフィールドファイルを受信しない

[-F]の場合:フィールド指定なし(YMODEMのみ)

【伝送方向】
 +R
 -R

"+R" ファイル受信
"-R" ファイル送信

【追加書込】
 +A
 -A

"+A" 既存データファイルに追加書込み
"-A" 追加書き込みしない

【CR-LFの扱い】
 +C
 -C

"+C" CR-LFをデータとする
"-C" CR-LFをレコードの区切り

送信の場合："TEST.DAT +P5 +F16,12 -R"
受信の場合："TEST.DAT +P5 +F16,12 +R"

Module Module1
    Declare Function ExecProtocol Lib "Bhtprtdm.dll" ( _
        ByVal hWnd As IntPtr, _
        ByVal Param As String, _
        ByVal TransferFileName As System.Text.StringBuilder, _
        ByVal ProtocolType As Integer) As Integer
End Module

Public Class Form1
    '送信処理ボタン
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Try
            Const PRTCL_YMODEMBATCH As Short = 2
            Dim iRet As Integer
            Dim strFile As System.Text.StringBuilder = New System.Text.StringBuilder
            Dim strOption As String
            'オプションの編集
            strOption = "TEST.DAT +P5 +F16,12 -R"   '"-R"送信
            'ファイル転送
            iRet = ExecProtocol(Me.Handle, strOption, strFile, PRTCL_YMODEMBATCH)
            '戻り値のチェック
            If iRet <> 0 Then
                MsgBox("Err Code = " & iRet.ToString() & " : File[" & strFile.ToString() & "]")
            Else
                MsgBox("送信OK...File[" & strFile.ToString() & "]")
            End If
        Catch ex As Exception
            MsgBox(ex.ToString)
        End Try
    End Sub

    '受信処理ボタン
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Try
            Const PRTCL_YMODEMBATCH As Short = 2
            Dim iRet As Integer
            Dim strFile As System.Text.StringBuilder = New System.Text.StringBuilder
            Dim strOption As String
            'オプションの編集
            strOption = "TEST.DAT +P5 +R"   '"+R"受信
            'ファイル転送
            iRet = ExecProtocol(Me.Handle, strOption, strFile, PRTCL_YMODEMBATCH)
            '戻り値のチェック
            If iRet <> 0 Then
                MsgBox("Err Code = " & iRet.ToString() & " : File[" & strFile.ToString() & "]")
            Else
                MsgBox("受信OK...File[" & strFile.ToString() & "]")
            End If
        Catch ex As Exception
            MsgBox(ex.ToString)
        End Try
    End Sub
End Class

'---------------------------------------
'ファイル送信
'---------------------------------------
'Function GfSndFile%(pintFp%, pstrSpeed$, pstrFile$, pstrOption$)
'引　数：
'	pintFp%		：ファイル番号
'	pstrSpeed$	：送信スピード
'	pstrFile$	：送信ファイル名
'	pstrOption$	：送信オプション
'戻り値:
'	GfSndFile%	:送信OK(GcTrue%)NG(GcFalse%)
'---------------------------------------
	Function GfSndFile%(pintFp%, pstrSpeed$, pstrFile$, pstrOption$)
		On Error Goto GfSndFile.ErrProc
		OPEN "COM1:" + pstrSpeed$ AS pintFp%
		XFILE pstrFile$, pstrOption$
		GfSndFile% = GcTrue%
GfSndFile.Return		'終了処理
		CLOSE pintFp%
		On Error Goto 0
		Exit Function
'-----
'エラー処理
'-----
GfSndFile.ErrProc
		GfSndFile% = GcFalse%
		Resume GfSndFile.Return
	End Function

'---------------------------------------
'ファイル受信
'---------------------------------------
'Function GfRcvFile%(pintFp%, pstrSpeed$, pstrFile$, pstrOption$)
'引　数：
'	pintFp%		：ファイル番号
'	pstrSpeed$	：受信スピード
'	pstrFile$	：受信ファイル名
'	pstrOption$	：受信オプション（"R"）以外のオプション
'戻り値:
'	GfRcvFile%	:受信OK(GcTrue%)NG(GcFalse%)
'---------------------------------------
	Function GfRcvFile%(pintFp%, pstrSpeed$, pstrFile$, pstrOption$)
		On Error Goto GfRcvFile.ErrProc
		OPEN "COM1:" + pstrSpeed$ AS pintFp%
		OUT &h6060, 3	'YMODEM
		XFILE pstrFile$, "R" + pstrOption$
		GfRcvFile% = GcTrue%
GfRcvFile.Return		'終了処理
		CLOSE pintFp%
		On Error Goto 0
		Exit Function
'-----
'エラー処理
'-----
GfRcvFile.ErrProc
		GfRcvFile% = GcFalse%
		Resume GfRcvFile.Return
	End Function

'---------------------------------------
'メイン処理開始
'---------------------------------------
	SCREEN 1				'漢字モード
	LOCATE , , 2			'カーソルをブロック表示
	PRIVATE intRet%
	PRINT "受信開始:";
	intRet% = GfRcvFile%(1, "115200", "TEST.DAT", "PTM") '受信
	PRINT "GfRcvFile%=" + STR$(intRet%)
	WAIT 0, &h01 'キー入力待ち
	PRINT "送信開始:";
	intRet% = GfSndFile%(1, "115200", "TEST.DAT", "PTM") '送信
	PRINT "GfSndFile%=" + STR$(intRet%)
	WAIT 0, &h01 'キー入力待ち
	END

* created by BHT-BASIC 4.0 Transfer Utility DLL Version 1.14
*   Copyright (C) DENSO WAVE INC. 2001-2013 all rights reserved
file	TEST.DAT
fields	16 12

* created by BHT
file	TEST.DAT
size	150
records	5
fields	16 12