VB.NET-TIPS などプログラミングについて

前回はWord文書の中で文字列を検索しその部分を指定された文字列で置き換える処理を作成しましたが、 カーソルの位置が最後の置換処理を行った場所に移動します。

⇒access vba でのWord文書の文字列検索と置換について（Word処理用クラスに文字列置換関数を追加）

これでは文書の途中にカーソルがありますので、文書の先頭が見たい場合には都合が悪いので、カーソルを先頭に移動する関数を作成します。
カーソルの移動には Bookmark オブジェクトを利用します。 このオブジェクトには以下の様に定義済みのものがありますのでこれを利用します。

この Bookmark オブジェクトに \StartOfDoc を指定し、そのオブジェクトを選択することでカーソル移動が行えます。 関数としては以下の通りで、特に難しくはありません。
尚、 Range オブジェクトを使ってもできます。

Word文書カーソル先頭移動関数

'******************************************************************************
' Word文書・カーソル先頭移動
'******************************************************************************
' 関数名 : WordMoveToTop()
'******************************************************************************
Public Sub WordMoveToTop()
    On Error GoTo Err_WordMoveToTop
    
    'カーソル先頭移動
    WordDoc.Bookmarks("\StartOfDoc").Select
    '以下の方法でもOK
    'WordDoc.Range(0, 0).Select

Exit_WordMoveToTop:
    Exit Sub

Err_WordMoveToTop:
    MsgBox Err.Description
    Resume Exit_WordMoveToTop
End Sub

この関数をWord処理用クラスに追加して、それを使用する例として、access フォームに１個のボタンのみを設置し、そのクリックイベントでワード文書を開く様にしてみます。

Word文書文字列置換関数の使用例

Option Compare Database

' クラスWordオブジェクト
Private mclsWord As clsWord

'------------------------------------------------------------------------------
' フォームロード時イベント
'------------------------------------------------------------------------------
Private Sub Form_Load()
    Set mclsWord = New clsWord
End Sub

'------------------------------------------------------------------------------
' フォームクローズイベント
'------------------------------------------------------------------------------
Private Sub Form_Close()
    'ワードクローズ
    mclsWord.WordClose
    'Wordオブジェクト解放
    Set mclsWord = Nothing
End Sub

'------------------------------------------------------------------------------
' コマンド1開始
'------------------------------------------------------------------------------
Private Sub コマンド1_Click()
    Dim strPath As String
    'ワードファイルを読み込み、文章を編集する状態にする
    strPath = Application.CurrentProject.path & "\" & "find-test.docx"
    'ワードファイルを読込み編集状態で表示する
    mclsWord.WordOpen strPath, True
    '
    Dim arrVaKey() As Variant
    Dim arrVaVal() As Variant

    arrVaKey = Array("@test1@", _
                     "@test2@", _
                     "@test3@", _
                     "@test4@")
    arrVaVal = Array("テスト１", _
                     "テスト２", _
                     "テスト３", _
                     "テスト４－１" & vbCrLf & "テスト４－２" & vbCrLf & "テスト４－３")
    '置換処理(左揃えを行わない)
    mclsWord.WordReplace arrVaKey, arrVaVal, False
    
    arrVaKey = Array("@test5@")
    arrVaVal = Array("テスト５－１" & vbCrLf & "テスト５－２" & vbCrLf & "テスト５－３")
    '置換処理(左揃えを行う)
    mclsWord.WordReplace arrVaKey, arrVaVal, True
    '先頭へ移動
    mclsWord.WordMoveToTop
End Sub

「コマンド1開始」を押下することで、ワードが起動し置換処理の結果が表示され、カーソルが先頭に移動していることが分かります。

関連する記事